home *** CD-ROM | disk | FTP | other *** search
/ Power Programmierung / Power-Programmierung (Tewi)(1994).iso / assemblr / tools / trace / trace.asm < prev    next >
Assembly Source File  |  1986-04-08  |  70KB  |  2,932 lines
  1.     page    60,132
  2.     .lfcond
  3.     title    "TRACE - Interrupt Tracer"
  4.     subttl    Introduction
  5.     page
  6.     comment    \
  7.  
  8. TRACE is an INT tracer. It traps INT's, traces the registers at the entry
  9. to the INT, executes the INT itself, and then traces the regs at exit from
  10. the INT. It also allows the user at the keyboard to see all of this traced
  11. information, either at the screen or on the printer.
  12.  
  13. The INT's that are to be traced are specified in the source code (see config
  14. section below). Once defined, they may be enabled or disabled from the
  15. keyboard.
  16.  
  17.       <<< REBOOT AS SOON AS POSSIBLE AFTER INVOKING TRACE!!! >>>
  18.  
  19. This is not foolproof or bugfree. We use it 'cause it's a terrific tool
  20. for deprotecting copy-protected software. You use it at your own risk.
  21. When you've gotten a printout of the trace activity that interests you,
  22. reboot your system. Don't say that we didn't warn you.
  23.  
  24. Enjoy.
  25.  
  26.     \
  27.     page
  28. code    segment    para 'code'
  29.     assume    cs:code,ds:code
  30.     org    0100h
  31. start:    jmp    init
  32.  
  33. ;********************************************************
  34. ;
  35. ; Definition of one interrupt control table
  36. ;
  37. ;********************************************************
  38.  
  39. ICT             struc
  40. ICT_flags       db      ?       ;See below
  41. ICT_intnum      db      ?       ;interrupt # this table belongs to
  42. ICT_AH_lo       db      ?       ;lower AH limit to trace
  43. ICT_AH_hi       db      ?       ;upper AH limit to trace
  44. ICT_orig_hndlr  dd      ?       ;cs:ip of original handler
  45. ICT_hits    dw      ?       ;# traces made for this ICT
  46. ICT_num        db      ?       ;ICT number (0-7)
  47. ICT             ends
  48.  
  49. ;
  50. ; Equates for flags byte of ICT
  51. ;
  52.  
  53. F_ACTIVE    equ    10000000b    ;Bit 7 = this ICT is active
  54. F_RET        equ    01000000b    ;Bit 6 = This INT exits via RET
  55. F_RET2        equ    00100000b    ;Bit 5 = This INT exits via RET2
  56. F_IRET        equ    00010000b    ;Bit 4 = This INT exits via IRET
  57. F_ENABLE    equ    00001000b    ;Bit 3 = Tracing enabled for this ICT
  58. F_FCB        equ    00000100b    ;Bit 2 = enable FCB/ASCII traces for INT 21h
  59. F_ROM        equ    00000010b    ;Bit 1 = exclude ROM invocations of this INT
  60. F_BELOW        equ    00000001b    ;Bit 0 = exclude invokers below us (DOS etc)
  61.  
  62.     page
  63. ;*******************************************************
  64. ;    B E G I N     C O N F I G U R A T I O N
  65. ;*******************************************************
  66.  
  67. ;
  68. ; Set trace_size to number of bytes to set aside for trace table.
  69. ;
  70.  
  71. trace_size    equ    30000
  72.  
  73. ;
  74. ; Set peri_int to the interrupt number (usually 060H) to be used
  75. ; by Periscope to invoke our reporting routines.
  76. ;
  77.  
  78. peri_int    equ    060h
  79.  
  80. ;
  81. ; Set prt_scr non-zero to assemble code that allows control via SHIFT-PrtSc.
  82. ;
  83.  
  84. prt_scr        equ    1
  85.  
  86. ;
  87. ; Set use_prt non-zero to start up using the printer instead of the screen
  88. ;
  89.  
  90. use_prt        equ    0
  91.  
  92. ;
  93. ; Set num_feeds to number of extra Linefeeds to send to printer to jack
  94. ; up the paper enough to let you read it, after display of menus etc.
  95. ;
  96.  
  97. num_feeds    equ    10
  98.  
  99.  
  100. ;
  101. ; Define interrupts to be traced by filling in the following ICT's.
  102. ; Note that there are only 8. That's the max that can be traced.
  103. ; Note that the F_ACTIVE flag must be set in used ICT's, and off in
  104. ; those that aren't defining something that you want traced.
  105. ;
  106. ; Don't mess with the last 3 fields in the ICT!!! Leave 'em as-is.
  107. ;
  108. ;   It is EXTREMELY important that you specify how the interrupt exits.
  109. ;   Set exactly one of the following flag bits:
  110. ;
  111. ;   F_RET   Interrupt exits via simple far RET, leaving original interrupts
  112. ;           on the stack for the caller to pop. INT's 025H and 026H are prime
  113. ;           examples.
  114. ;
  115. ;   F_RET2  Interrupt exits via RET 2, dropping original flags and returning
  116. ;           flags as set by interrupt handler. INT 021H (and anybody else
  117. ;           that uses flags like CARRY or ZERO to reflect results) does this.
  118. ;
  119. ;   F_IRET  Interrupt exits via IRET, restoring original flags from stack.
  120. ;           Hardware interrupt handlers do this, and many ROM BIOS routines.
  121. ;
  122. ;   Note that some interrupts may exit differently, depending on the specific
  123. ;   function requested. You may want to define several ICT's for a given
  124. ;   interrupt, each handling a different AH range.
  125. ;
  126. ;
  127.  
  128. ict0    ICT     <F_ACTIVE+F_RET2+F_ENABLE+F_FCB,021H,0dh,0ffh,0,0,0>    ;DOS funcs 0Dh thru FFh
  129. ict1    ICT     <F_ACTIVE+F_RET2+F_ENABLE,013H,0,0ffh,0,0,1>        ;ROM BIOS INT 13h (all)
  130. ict2    ICT     <F_ACTIVE+F_RET2,021H,0,0ch,0,0,2>            ;DOS funcs 00h thru 0Ch
  131. ict3    ICT     <F_ACTIVE+F_RET+F_ENABLE,025h,0,0ffh,0,0,3>        ;RAW disk I/O
  132. ict4    ICT     <F_ACTIVE+F_RET+F_ENABLE,026h,0,0ffh,0,0,4>        ;RAW disk I/O
  133. ict5    ICT     <0,0,0,0,0,0,5>                        ;unused
  134. ict6    ICT     <0,0,0,0,0,0,6>                        ;unused
  135. ict7    ICT     <0,0,0,0,0,0,7>                        ;unused
  136.  
  137.  
  138. ;*******************************************************
  139. ;    E N D    C O N F I G U R A T I O N
  140. ;*******************************************************
  141.     page
  142. ;
  143. ; Trace entry byte zero (the type byte) identifies entry as follows:
  144. ; 
  145. ;   Bits 7-4 = trace type
  146. ;
  147. ;               0000 = BEFORE int was executed
  148. ;               0001 = AFTER int was executed
  149. ;               0010 = FCB referenced by an INT 21h
  150. ;               0011 = ASCIIZ referenced by an INT 21h
  151. ;
  152. ;   Bit 3    = RESERVED
  153. ;
  154. ;   Bits 2-0 = ICT # (0-7) which made this trace record
  155. ;
  156. ; Record formats are as follows:
  157. ;
  158.  
  159. BEFORE        struc        ;BEFORE trace entry
  160. B_type        db    ?    ;see above
  161. B_int        db    ?    ;INT # that was trapped
  162. B_ax        dw    ?    ;Regs BEFORE executing INT
  163. B_bx        dw    ?
  164. B_cx        dw    ?
  165. B_dx        dw    ?
  166. B_es        dw    ?
  167. B_ds        dw    ?
  168. B_ss        dw    ?
  169. B_sp        dw    ?
  170. B_si        dw    ?
  171. B_di        dw    ?
  172. B_bp        dw    ?
  173. B_cs        dw    ?    ;CS of invoker of INT
  174. B_ip        dw    ?    ;IP of invoker
  175. BEFORE        ends
  176.  
  177. AFTER        struc        ;AFTER record type
  178. A_type        db    ?    ;see above
  179. A_int        db    ?    ;INT # that was executed
  180. A_ax        dw    ?    ;Regs AFTER executing INT
  181. A_bx        dw    ?
  182. A_cx        dw    ?
  183. A_dx        dw    ?
  184. A_es        dw    ?
  185. A_ds        dw    ?
  186. A_si        dw    ?
  187. A_di        dw    ?
  188. A_bp        dw    ?
  189. A_flags        dw    ?    ;Flags AFTER doing INT
  190. AFTER        ends
  191.  
  192. FCB        struc            ;INT 21h FCB record
  193. FCB_type     db    ?        ;see above
  194. FCB_int        db    ?        ;INT # that was executed (21h)
  195. FCB_drive    db    ?        ;drive field of FCB
  196. FCB_name    db    "????????"    ;filename field of FCB
  197. FCB_ext        db    "???"        ;extension field of FCB
  198. FCB        ends
  199.  
  200. ASCIIZ        struc            ;INT 21h ASCIIZ record
  201. AZ_type     db    ?        ;see above
  202. AZ_int        db    ?        ;INT # that was executed (21h)
  203. AZ_str        db    "?????????????????????????????????????????????????????????????????"
  204. ASCIIZ        ends
  205.  
  206.     subttl  Resident Storage
  207.     page
  208.  
  209. ;
  210. ; Things defined here are present even after we become resident and
  211. ; exit to DOS.
  212. ;
  213.  
  214. ;
  215. ; Definitions used by print_edit()
  216. ;
  217.  
  218. Edit_End    equ    0f0h    ;End of input line
  219. Edit_Byte    equ    0f1h    ;Next byte is 8-bit value to be printed in hex
  220. Edit_Word    equ    0f2h    ;Next 2 bytes are 16-bit value to be printed in hex
  221. Edit_Line    equ    0f3h    ;Next 2 bytes are address of string for print_line()
  222. Edit_Call    equ    0f4h    ;Next byte is AH arg, next 2 are DX arg,
  223.                 ;and next 2 are subroutine address to call
  224. Edit_Dec8    equ    0f5h    ;Next byte is 8-bit value to be printed as decimal
  225. Edit_Dec16    equ    0f6h    ;Next 2 bytes are 16-bit value to be printed as decimal
  226. Edit_Skip    equ    0f7h    ;Ignore this byte (don't display it)
  227.  
  228. ;********************************************************
  229. ;
  230. ; Index table pointing to all ICT's
  231. ;
  232. ;********************************************************
  233.  
  234. ict_index label word
  235.     dw      offset ict0
  236.     dw      offset ict1
  237.     dw      offset ict2
  238.     dw      offset ict3
  239.     dw      offset ict4
  240.     dw      offset ict5
  241.     dw      offset ict6
  242.     dw      offset ict7
  243.  
  244. ;********************************************************
  245. ;
  246. ; Index table pointing to all handlers
  247. ;
  248. ;********************************************************
  249.  
  250. hndlr_index label word
  251.     dw      offset handler0
  252.     dw      offset handler1
  253.     dw      offset handler2
  254.     dw      offset handler3
  255.     dw      offset handler4
  256.     dw      offset handler5
  257.     dw      offset handler6
  258.     dw      offset handler7
  259.  
  260. ;********************************************************
  261. ;
  262. ; Trace table itself, with plenty of room
  263. ;
  264. ;********************************************************
  265.  
  266. next_byte       dw      offset trace_table      ;address of next entry
  267.  
  268. trace_table     db      trace_size dup (0)
  269.  
  270. last_byte       db      80 dup (0)          ;sloppy way of handling overflow
  271.  
  272. ;********************************************************
  273. ;
  274. ; Table of sizes for each trace record type. Must be in same
  275. ; order as record types themselves.
  276. ;
  277. ;********************************************************
  278.  
  279. rec_sizes    label    word
  280.         dw    size BEFORE
  281.         dw    size AFTER
  282.         dw    size FCB
  283.         dw    size ASCIIZ
  284.  
  285. ;********************************************************
  286. ;
  287. ; Table of INT 21h functions that include an FCB pointer in DS:DX
  288. ;
  289. ;********************************************************
  290.  
  291. FCB_table    label    byte
  292.         db    0fh,10h,11h,12h,13h,14h,15h,16h,17h,21h,22h,23h,24h,27h,28h
  293. FCB_end        label    byte
  294.  
  295.  
  296. ;********************************************************
  297. ;
  298. ; Table of INT 21h functions that include an ASCIIZ pointer in DS:DX
  299. ;
  300. ;********************************************************
  301.  
  302. ASCIIZ_table    label    byte
  303.         db    4bh,3ch,3dh,41h,43h,4eh,56h,5ah,5bh,39h,3ah,3bh
  304. ASCIIZ_end    label    byte
  305.  
  306. ;********************************************************
  307. ;
  308. ; Misc storage
  309. ;
  310. ;********************************************************
  311.  
  312. our_cs          dw      0               ;our CS (not for segment checking)
  313. test_cs         dw      0               ;our normalized CS (for segment checking)
  314. long_addr       dd      0               ;for long JMP's and CALLs
  315. our_ICT         dw      0               ;for quick save of our ICT pointer
  316. our_flags    db    0            ;for quick save of our ICT flags
  317. prt_base    dw    0            ;base I/O address of printer
  318. prt_flag    db    0            ;non-zero to send output to printer
  319.         db    255 dup (0)        ;stack for Periscope Int handler
  320. our_tos        dw    0            ;top of that stack
  321. stack_inuse    db    0            ;non-zero when above stack is in use
  322. save_ss        dw    0            ;for stack-swapping
  323. save_sp        dw    0
  324.  
  325.  
  326.     subttl  Interrupt Trappers and Tracing
  327.     page
  328.  
  329. ;********************************************************
  330. ;
  331. ; Interrupt handler entry points for each ICT
  332. ;
  333. ;********************************************************
  334.  
  335. handler macro   ictloc
  336.     cli                ;*** NO INTERRUPTS!!! ***
  337.     push    bp              ;save stack pointer, so that...
  338.     mov     bp,sp           ;...we can ref things via BP
  339.     push    bx              ;set BX to point to ICT
  340.     mov     bx,offset cs:ictloc
  341.     jmp     short int_common    ;goto common code
  342.     endm
  343.  
  344. interrupt proc  far
  345.  
  346. handler0:
  347.     handler ict0
  348.  
  349. handler1:
  350.     handler ict1
  351.  
  352. handler2:
  353.     handler ict2
  354.  
  355. handler3:
  356.     handler ict3
  357.  
  358. handler4:
  359.     handler ict4
  360.  
  361. handler5:
  362.     handler ict5
  363.  
  364. handler6:
  365.     handler ict6
  366.  
  367. handler7:
  368.     handler ict7
  369.  
  370.  
  371. int_common:
  372.  
  373.     push    ax
  374.  
  375. ;********************************************************
  376. ;
  377. ; Common code for all trapped INT's.
  378. ;
  379. ; At this point:
  380. ;
  381. ;   BX holds ICT address.
  382. ;   BP points to stack as follows:
  383. ;
  384. ;                   AX
  385. ;                   BX
  386. ;      (BP) ---->   BP
  387. ;               +2  IP    of caller
  388. ;               +4  CS    of caller
  389. ;               +6  FLAGS of caller
  390. ;
  391. ;********************************************************
  392.  
  393.     test    cs:[bx].ICT_flags,F_ENABLE    ;tracing enabled for this ICT?
  394.     jz      no_trace                ;no, don't trace it
  395.     cmp     ah,cs:[bx].ICT_AH_lo        ;is AH within bounds?
  396.     jb      no_trace                ;no, don't trace it
  397.     cmp     ah,cs:[bx].ICT_AH_hi
  398.     ja      no_trace                ;no, don't trace it
  399.  
  400. ;
  401. ; See if we should check caller's CS:IP
  402. ;
  403.  
  404.     test    cs:[bx].ICT_flags,F_BELOW+F_ROM
  405.  
  406.     jz      int_common3         ;no segment checks to be made
  407.     mov     ax,2[bp]        ;get caller's IP
  408.     shr     ax,1            ;prepare to normalize segment #
  409.     shr     ax,1
  410.     shr     ax,1
  411.     shr     ax,1
  412.     add     ax,4[bp]        ;add in segment
  413.  
  414. ;
  415. ; ------ AX now equals normalized segment #
  416. ;
  417.  
  418.     test    cs:[bx].ICT_flags,F_BELOW
  419.  
  420.     jz      int_common2         ;don't check for invoker below us
  421.     cmp     ax,cs:test_cs        ;is caller below us?
  422.     jb      no_trace        ;yes, don't trace
  423.  
  424. int_common2:
  425.  
  426.     test    cs:[bx].ICT_flags,F_ROM
  427.  
  428.     jz      int_common3         ;don't check for invoker in ROM
  429.     cmp     ax,0c000h           ;is caller in ROM?
  430.     jae     no_trace        ;yes, don't trace
  431.  
  432. int_common3:
  433.  
  434. ;
  435. ; See if we have room for this trace
  436. ;
  437.  
  438.     mov     ax,cs:next_byte     ;get address of next entry
  439.     push    ax
  440.     add    ax,size BEFORE        ;add size of this record
  441.     cmp     ax,offset cs:last_byte  ;would record fit?
  442.     pop    ax
  443.     jb      yes_trace           ;yes, there's room
  444.  
  445. no_trace:
  446.  
  447. ;
  448. ; We are not to trace this INT, for whatever reason.
  449. ; Just go to original handler, and return to caller (not to us).
  450. ;
  451.  
  452.     mov     ax,word ptr cs:[bx].ICT_orig_hndlr
  453.     mov     word ptr cs:long_addr,ax
  454.     mov     ax,word ptr cs:[bx].ICT_orig_hndlr+2
  455.     mov     word ptr cs:long_addr+2,ax
  456.     pop     ax
  457.     pop     bx
  458.     pop     bp
  459.     jmp     cs:long_addr    ;let original handler return to caller
  460.  
  461.  
  462. yes_trace:
  463.  
  464. ;
  465. ; We are to proceed with trace of this INT. Make trace entry.
  466. ;
  467.  
  468.     push    es
  469.     push    di
  470.  
  471. ;
  472. ; At this point:
  473. ;
  474. ;   AX holds offset to next trace entry.
  475. ;   BX holds ICT address.
  476. ;   BP points to stack as follows:
  477. ;
  478. ;                   DI
  479. ;                   ES
  480. ;                   AX
  481. ;                   BX
  482. ;      (BP) ---->   BP
  483. ;               +2  IP    of caller
  484. ;               +4  CS    of caller
  485. ;               +6  FLAGS of caller
  486. ;
  487.  
  488.     mov     di,ax           ;set ES:DI to next trace entry
  489.     mov     ax,cs
  490.     mov     es,ax
  491.     cld                     ;forward!!!
  492.     mov     ah,cs:[bx].ICT_intnum   ;get interrupt # being traced
  493.     mov     al,cs:[bx].ICT_num    ;get ICT #, make BEFORE record type
  494.     stosw
  495.     mov     ax,-4[bp]           ;original AX
  496.     stosw
  497.     mov     ax,-2[bp]           ;original BX
  498.     stosw
  499.     mov     ax,cx
  500.     stosw
  501.     mov     ax,dx
  502.     stosw
  503.     mov     ax,-6[bp]           ;original ES
  504.     stosw
  505.     mov     ax,ds
  506.     stosw
  507.     mov     ax,ss
  508.     stosw
  509.     mov     ax,bp           ;original SP
  510.     add     ax,2
  511.     stosw
  512.     mov     ax,si
  513.     stosw
  514.     mov     ax,-8[bp]           ;original DI
  515.     stosw
  516.     mov     ax,[bp]         ;original BP
  517.     stosw
  518.     mov     ax,4[bp]        ;caller's CS
  519.     stosw
  520.     mov     ax,2[bp]        ;caller's IP
  521.     stosw
  522.  
  523.     mov     cs:next_byte,di     ;save spot for next trace entry
  524.     inc    cs:[bx].ICT_hits    ;bump number of traces made for this ICT
  525.  
  526. ;
  527. ; We're done with the BEFORE trace. See if we are to do an FCB or ASCIIZ
  528. ; trace record.
  529. ;
  530.  
  531.     test    cs:[bx].ICT_flags,F_FCB
  532.     jz    no_FCB            ;no, we are definitely not supposed to
  533.     cmp    cs:[BX].ICT_intnum,021h    ;is this an INT 21h?
  534.     jnz    no_FCB            ;no, can't trace it then
  535.  
  536. ;
  537. ; Search through ASCIIZ function table, to see if function that was called
  538. ; is one that contains an ASCIIZ pointer in DS:DX
  539. ;
  540.  
  541.     mov    ax,-4[bp]        ;get AX at time of call
  542.     push    cx
  543.     mov    di,offset cs:ASCIIZ_table
  544.     mov    cx,offset cs:ASCIIZ_end
  545.     sub    cx,di            ;CX now has size of table
  546.     mov    al,ah            ;get function to AL
  547.     repnz    scasb            ;see if it's in table
  548.     pop    cx
  549.     jz    trace_ASCIIZ        ;it's there, so do ASCIIZ trace
  550.  
  551. ;
  552. ; Search through FCB function table, to see if function that was called
  553. ; is one that contains an FCB pointer in DS:DX
  554. ;
  555.  
  556.     push    cx
  557.     mov    di,offset cs:FCB_table
  558.     mov    cx,offset cs:FCB_end
  559.     sub    cx,di            ;CX now has size of table
  560.     repnz    scasb            ;see if it's in table
  561.     pop    cx
  562.     jnz    no_FCB            ;no FCB or ASCIIZ trace called for
  563.  
  564. ;
  565. ; We are to do trace of FCB pointed to by DS:DX
  566. ;
  567.  
  568.     mov    al,00100000b        ;trace record number for FCB trace
  569.     mov    ah,size FCB        ;size of record
  570.     jmp    short trace_common    ;rest is common code
  571.  
  572. trace_ASCIIZ:
  573.  
  574. ;
  575. ; We are to do trace of ASCIIZ string pointed to by DS:DX
  576. ;
  577.  
  578.     mov    al,00110000b        ;trace record number for ASCIIZ trace
  579.     mov    ah,size ASCIIZ        ;size of record
  580.  
  581. trace_common:
  582.  
  583. ;
  584. ; Copy bytes from DS:DX to new ASCIIZ or FCB trace record.
  585. ;
  586. ; At this point:
  587. ;
  588. ;   AL holds trace record type, properly positioned in bits 7-4
  589. ;   AH holds size of record that we're doing (the full record)
  590. ;
  591.  
  592.     sub    ah,2            ;minus two bytes for record header
  593.     mov    di,cs:next_byte        ;see if there's room...
  594.     push    di
  595.     push    ax
  596.     mov    al,ah            ;get record size to AX
  597.     xor    ah,ah
  598.     add    di,ax
  599.     cmp    di,offset cs:last_byte
  600.     pop    ax
  601.     pop    di
  602.     jae    no_FCB            ;no room
  603.     push    ax            ;save AX over this
  604.     mov    ah,cs:[bx].ICT_intnum    ;start header with interrupt #
  605.     or    al,cs:[bx].ICT_num    ;add ICT number to trace type
  606.     stosw                ;start new record with it
  607.     pop    ax            ;restore AX
  608.     push    cx
  609.     push    si
  610.     mov    si,dx            ;access DS:DX as DS:SI
  611.     mov    cl,ah            ;record size to CX
  612.     xor    ch,ch
  613.     rep    movsb            ;that's how many to copy
  614.     pop    si
  615.     pop    cx
  616.     mov    cs:next_byte,di        ;save offset to next record
  617.  
  618. no_FCB:                    ;end of FCB/ASCIIZ tracing
  619.  
  620.  
  621. ;
  622. ; Having traced all of those, now invoke original interrupt handler. Have
  623. ; it return to us, not the original caller of the interrupt.
  624. ;
  625.  
  626.     mov     cs:our_ICT,bx       ;save ICT pointer for a nanosecond
  627.     mov    al,cs:[bx].ICT_flags    ;save copy of flags that we can get to
  628.     mov    cs:our_flags,al
  629.  
  630.     mov     ax,word ptr cs:[bx].ICT_orig_hndlr
  631.     mov     word ptr cs:long_addr,ax
  632.     mov     ax,word ptr cs:[bx].ICT_orig_hndlr+2
  633.     mov     word ptr cs:long_addr+2,ax
  634.  
  635.     pop     di
  636.     pop     es
  637.     pop     ax
  638.     pop     bx
  639.     pop     bp
  640.     push    cs:our_ICT          ;save ICT pointer on stack
  641.     test    cs:our_flags,F_RET    ;should we push flags?
  642.     jnz    no_flags        ;no, cause they'd be left on stack
  643.     pushf                   ;yes, give handler some flags to drop
  644.  
  645. no_flags:
  646.     call    cs:long_addr        ;invoke original handler
  647.  
  648.  
  649. ;
  650. ; We're back from the real interrupt handler, and can make the "after" trace.
  651. ; Our ICT address is on stack.
  652. ;
  653.  
  654.     sti                ;give world a crack at interrupts
  655.     nop
  656.     nop
  657.     cli                ;*** NO INTERRUPTS!!! ***
  658.     push    bp              ;establish stack reference
  659.     mov     bp,sp
  660.     pushf                   ;save resultant flags
  661.     push    es
  662.     push    di
  663.     push    ax
  664.     push    bx
  665.  
  666. ;
  667. ; At this point:
  668. ;
  669. ;                     BX
  670. ;                     AX
  671. ;                     DI
  672. ;                     ES
  673. ;                     FLAGS (as returned by real interrupt)
  674. ;     (BP) -------->  BP
  675. ;                     ICT address
  676. ;                     IP of caller
  677. ;                     CS of caller
  678. ;                     FLAGS of original caller
  679. ;
  680.  
  681.     mov     bx,2[bp]        ;recover ICT address
  682.     mov     di,cs:next_byte     ;room for "after" trace entry?
  683.     push    di
  684.     add    di,size AFTER
  685.     cmp     di,offset cs:last_byte
  686.     pop    di
  687.     jae     no_after        ;no, skip it
  688.     mov     ax,cs           ;make ES:DI point to next entry
  689.     mov     es,ax
  690.     cld                     ;forward!!!
  691.     mov     ah,cs:[bx].ICT_intnum   ;get interrupt #
  692.     mov     al,cs:[bx].ICT_num    ;get ICT #, make AFTER record type
  693.     or    al,00010000b
  694.     stosw
  695.     mov     ax,-8[bp]           ;AX at int's return
  696.     stosw
  697.     mov     ax,-10[bp]          ;BX at int's return
  698.     stosw
  699.     mov     ax,cx
  700.     stosw
  701.     mov     ax,dx
  702.     stosw
  703.     mov     ax,-4[bp]           ;ES at int's return
  704.     stosw
  705.     mov     ax,ds
  706.     stosw
  707.     mov     ax,si
  708.     stosw
  709.     mov     ax,-6[bp]           ;DI at int's return
  710.     stosw
  711.     mov     ax,[bp]         ;BP at int's return
  712.     stosw
  713.     mov     ax,-2[bp]           ;FLAGS at int's return
  714.     stosw
  715.  
  716.     mov     cs:next_byte,di     ;save offset to next entry
  717.  
  718. no_after:
  719.  
  720. ;
  721. ; All done making "after" trace, or we've skipped it cause there was
  722. ; no room for it.
  723. ;
  724. ; Now just exit back to the original caller.
  725. ;
  726.  
  727.     mov    al,cs:[bx].ICT_flags    ;save flags where we can get to them
  728.     mov    cs:our_flags,al
  729.     pop     bx
  730.     pop     ax
  731.     pop     di
  732.     pop     es
  733.     popf
  734.     pop     bp
  735.     pop     cs:our_ICT      ;drop ICT address without affecting flags
  736.  
  737. ;
  738. ; HOW we exit is extremely important. We must exit the same way that the
  739. ; real interrupt does.
  740. ;
  741.  
  742.     pushf                ;save current flags in case we return them
  743.     test    cs:our_flags,F_RET
  744.     jnz    exit_ret
  745.     test    cs:our_flags,F_RET2
  746.     jnz    exit_ret2
  747.  
  748. ;
  749. ; Assume IRET.
  750. ;
  751.  
  752. exit_iret:
  753.     popf            ;exit via IRET, reloading original flags
  754.     STI            ;Allow interrupts now
  755.     iret
  756.  
  757. exit_ret2:
  758.     popf            ;exit via RET 2, discarding original flags
  759.     STI            ;Allow interrupts now
  760.     ret    2
  761.  
  762. exit_ret:
  763.     popf            ;exit via far RET, leaving original flags
  764.     STI            ;Allow interrupts now
  765.     ret
  766.  
  767. interrupt endp
  768.  
  769.     subttl    Support routines - Printer & Screen I/O
  770.     page
  771. ;*****************************************
  772. ;
  773. ; Select video for subsequent output
  774. ;
  775. ;*****************************************
  776.  
  777. selvideo proc    near
  778.     mov    prt_flag,0
  779.     ret
  780. selvideo endp
  781.  
  782.  
  783. ;*****************************************
  784. ;
  785. ; Select printer for subsequent output
  786. ;
  787. ;*****************************************
  788.  
  789. selprint proc    near
  790.     push    ax
  791.     mov    ax,prt_base    ;do we have a printer?
  792.     or    al,ah
  793.     mov    prt_flag,al    ;al is non-zero if we do
  794.     pop    ax
  795.     ret
  796. selprint endp
  797.  
  798. ;********************************************************
  799. ;
  800. ; Output AL to printer or screen, depending on prt_flag.
  801. ;
  802. ;********************************************************
  803.  
  804. print    proc    near
  805.     push    dx
  806.     push    cx
  807.     push    bx
  808.     push    ax
  809.  
  810. ; ----- See if it should go to printer
  811.  
  812.     test    prt_flag,0ffh        ;send it to printer?
  813.     jnz    print1            ;yes
  814.  
  815. print0:
  816.  
  817. ;
  818. ; Send char to video via INT 010H
  819. ;
  820.  
  821.     mov    bl,1
  822.     mov    ah,14            ;"Write TTY" func
  823.     int    010h
  824.     clc                ;show no I/O error
  825.     jmp    short print9
  826.  
  827. print1:
  828.  
  829. ;----- Send it to printer
  830.  
  831.     mov    dx,prt_base        ;get printer base I/O address
  832.     inc    dx            ;up to status port
  833.     mov    ah,al            ;save char in ah
  834.     xor    cx,cx            ;init timeout ticker
  835.  
  836. print2:
  837.     in    al,dx            ;get status
  838.     test    al,080h            ;is printer busy?
  839.     jnz    print5            ;no, proceed to send char
  840.  
  841. ;
  842. ; We're not immediately ready. Some printers require more of a wait than
  843. ; the simple 64K loop found in CX. So here's a time waster that you may
  844. ; want to tailor to your printer.
  845. ;
  846.  
  847.     mov    al,8            ;greatly extend timeout value
  848.  
  849. print3:
  850.     dec    al
  851.     jnz    print3
  852.  
  853.     loop    print2            ;wait for whole timeout
  854.     stc                ;set carry for timeout
  855.     jmp    short print9        ;and exit
  856.  
  857. print5:
  858.     dec    dx            ;down to data reg
  859.     mov    al,ah            ;recover char to be sent
  860.     out    dx,al            ;put it on data lines
  861.     inc    dx            ;up to control port
  862.     inc    dx
  863.     mov    al,0dh            ;set strobe low
  864.     out    dx,al
  865.     mov    al,0ch            ;set strobe high again
  866.     out    dx,al
  867.     clc                ;show no error
  868.  
  869. print9:
  870.  
  871. ;
  872. ; At this point, CARRY is SET if we were going to the printer and had an
  873. ; I/O error.
  874. ;
  875.  
  876.     jnc    print10            ;no error
  877.     call    selvideo        ;error, so switch to video
  878.     pop    ax            ;recover AL
  879.     push    ax
  880.     jmp    print0            ;go send it to video
  881.  
  882. print10:
  883.     pop    ax
  884.     pop    bx
  885.     pop    cx
  886.     pop    dx
  887.     ret
  888. print    endp
  889.  
  890. ;********************************************************
  891. ;
  892. ; Output binary AL as 2 hex digits
  893. ;
  894. ;********************************************************
  895.  
  896. print_hex proc    near
  897.     push    bx
  898.     push    ax
  899.     mov    bl,al            ;isolate HO nibble
  900.     shr    bl,1
  901.     shr    bl,1
  902.     shr    bl,1
  903.     shr    bl,1
  904.     and    bx,0fh
  905.     mov    al,hextab[bx]        ;xlit to hex char
  906.     call    print            ;print 1st char
  907.     pop    ax
  908.     push    ax
  909.     mov    bl,al            ;isolate LO nibble
  910.     and    bx,0fh
  911.     mov    al,hextab[bx]        ;xlit to hex char
  912.     call    print            ;print 2nd char
  913.     pop    ax
  914.     pop    bx
  915.     ret
  916. print_hex endp
  917.  
  918. hextab    db    '0123456789ABCDEF'
  919.  
  920. ;********************************************************
  921. ;
  922. ; Output binary word AX as 4 hex digits
  923. ;
  924. ;********************************************************
  925.  
  926. print_word proc    near
  927.     xchg    ah,al            ;get HO half to AL
  928.     call    print_hex        ;print 1st 2 chars
  929.     xchg    ah,al            ;get LO half back to AL
  930.     call    print_hex        ;print 2nd 2 chars
  931.     ret
  932. print_word endp
  933.  
  934. ;********************************************************
  935. ;
  936. ; Output binary word AX as 4 hex digits, plus a blank
  937. ;
  938. ;********************************************************
  939.  
  940. print_wordb proc near
  941.     push    ax
  942.     call    print_word
  943.     mov    al,' '
  944.     call    print
  945.     pop    ax
  946.     ret
  947. print_wordb endp
  948.  
  949. ;*****************************************
  950. ;
  951. ; Print CRLF.
  952. ;
  953. ;*****************************************
  954.  
  955. crlf    proc    near
  956.     push    ax
  957.     mov    al,0dh
  958.     call    print
  959.     mov    al,0ah
  960.     call    print
  961.     pop    ax
  962.     ret
  963. crlf    endp
  964.  
  965. ;*****************************************
  966. ;
  967. ; Print string at DS:DX, up to "$" character.
  968. ;
  969. ;*****************************************
  970.  
  971. print_line proc    near
  972.     push    si
  973.     push    ax
  974.     cld            ;forward!
  975.     mov    si,dx        ;DS:SI = string
  976.  
  977. print_line2:
  978.     lodsb            ;get next byte to print
  979.     cmp    al,'$'        ;terminating char?
  980.     jz    print_line9    ;yes, exit
  981.     call    print        ;print this char
  982.     jmp    print_line2    ;continue till "$"
  983.  
  984. print_line9:
  985.     pop    ax
  986.     pop    si
  987.     ret
  988. print_line endp
  989.  
  990. ;*****************************************
  991. ;
  992. ; Print DX (HO), AX (LO) as xxxx:xxxx.
  993. ;
  994. ;*****************************************
  995.  
  996. print_seg proc    near
  997.     push    ax
  998.     mov    ax,dx        ;get HO word first
  999.     call    print_word
  1000.     mov    al,':'        ;show seperator too
  1001.     call    print
  1002.     pop    ax        ;recover LO word
  1003.     call    print_word
  1004.     ret
  1005. print_seg endp
  1006.  
  1007. ;********************************************************************
  1008. ;
  1009. ; Print a line at [DX], edited.
  1010. ;
  1011. ; Line may contain Edit_xxxx escape characters, as defined above.
  1012. ;
  1013. ;********************************************************************
  1014.  
  1015. print_edit proc    near
  1016.     push    si
  1017.     push    dx
  1018.     push    cx
  1019.     push    bx
  1020.     push    ax
  1021.         mov    si,dx            ;use DS:SI to read line
  1022.         cld                ;forward!!!
  1023.  
  1024. print_edit2:
  1025.         lodsb                ;get next byte of line
  1026.         cmp    al,Edit_Byte        ;binary byte to expand?
  1027.         jnz    print_edit3        ;no
  1028.         lodsb                ;yes, get 8-bit value
  1029.         call    print_hex        ;print it as hex
  1030.  
  1031. print_edit2b:
  1032.         mov    al,'H'            ;tack "H" for HEX after it
  1033.  
  1034. print_edit2c:
  1035.         call    print
  1036.         jmp    print_edit2        ;go get next char
  1037.  
  1038. print_edit3:
  1039.         cmp    al,Edit_Word        ;16-bit binary to expand?
  1040.         jnz    print_edit4        ;no
  1041.         lodsw                ;yes, get 16-bit word
  1042.         call    print_word        ;display as hex
  1043.         jmp    print_edit2b        ;follow with 'H' and continue
  1044.  
  1045. print_edit4:
  1046.         cmp    al,Edit_Call        ;call another routine?
  1047.         jnz    print_edit5        ;no
  1048.         lodsb                ;yes, get AH argument
  1049.         mov    bh,al            ;save for a nano...
  1050.         lodsw                ;get DX argument
  1051.         mov    dx,ax
  1052.         lodsw                ;get address to call
  1053.         mov    cx,ax
  1054.         mov    ah,bh            ;recover AH argument to use
  1055.         push    si            ;save our precious SI
  1056.         call    cx            ;call the routine
  1057.         pop    si
  1058.         jmp    print_edit2        ;go get next char
  1059.  
  1060. print_edit5:
  1061.     cmp    al,Edit_Dec8        ;8-bit decimal value?
  1062.     jnz    print_edit6        ;no
  1063.     lodsb                ;yes, get 8-bit byte
  1064.     xor    ah,ah            ;clear HO byte
  1065.  
  1066. print_edit5b:
  1067.     call    print_dec        ;print AX as decimal
  1068.     jmp    print_edit2        ;go get next input char
  1069.  
  1070. print_edit6:
  1071.     cmp    al,Edit_Dec16        ;16-bit decimal value?
  1072.     jnz    print_edit7        ;no
  1073.     lodsw                ;yes, get 16-bit byte
  1074.     jmp    print_edit5b        ;print it and go get next char
  1075.  
  1076. print_edit7:
  1077.     cmp    al,Edit_End        ;end of input string?
  1078.     jnz    print_edit2c        ;no, assume ASCII char and print it
  1079.  
  1080.     pop    ax
  1081.     pop    bx
  1082.     pop    cx
  1083.     pop    dx
  1084.     pop    si
  1085.         ret
  1086. print_edit endp
  1087.  
  1088.  
  1089. ;**************************************************
  1090. ;
  1091. ; Print AX in decimal, suppressing leading zeroes
  1092. ;
  1093. ;**************************************************
  1094.  
  1095. print_dec proc    near
  1096.     push    dx
  1097.     push    cx
  1098.     push    bx
  1099.     push    ax
  1100.     mov    cx,10            ;divisor
  1101.     xor    dx,dx
  1102.     div    cx            ;DL=units, AX = answer
  1103.     mov    bh,dl            ;save units
  1104.     xor    dx,dx
  1105.     div    cx            ;DL=tens, AX = answer
  1106.     mov    bl,dl            ;get tens
  1107.     or    bx,03030h        ;make into 2 ASCII digits
  1108.     mov    word ptr dec_buf+3,bx
  1109.     div    cl            ;AH=hunds, AL = answer
  1110.     mov    bh,ah            ;save hundreds
  1111.     xor    ah,ah
  1112.     div    cl            ;AH=thous, AL = ten_thousands
  1113.     mov    bl,ah            ;get thous
  1114.     or    bx,03030h        ;make into 2 ASCII digits
  1115.     mov    word ptr dec_buf+1,bx
  1116.     or    al,030h            ;make ten-thousands into ASCII digit
  1117.     mov    byte ptr dec_buf,al
  1118.  
  1119. ;
  1120. ; Now edit out leading zeroes by advancing BX to 1st non-zero
  1121. ;
  1122.  
  1123.     mov    bx,offset dec_buf
  1124.     mov    cx,4            ;max # to suppress
  1125.  
  1126. print_dec2:
  1127.     cmp    byte ptr [bx],'0'
  1128.     jnz    print_dec5        ;found non-zero, so exit
  1129.     inc    bx            ;up to next digit
  1130.     loop    print_dec2
  1131.  
  1132. print_dec5:
  1133.  
  1134. ;
  1135. ; All set. Print from [BX] on...
  1136. ;
  1137.  
  1138.     mov    dx,bx
  1139.     call    print_line
  1140.     pop    ax
  1141.     pop    bx
  1142.     pop    cx
  1143.     pop    dx
  1144.     ret
  1145. print_dec endp
  1146.  
  1147. dec_buf    db    "99999$"
  1148.  
  1149.  
  1150. ;********************************************************************
  1151. ;
  1152. ; Print one string from a table of possible strings.
  1153. ;
  1154. ; On entry: AH holds selector
  1155. ;           DX holds table address
  1156. ;
  1157. ; Each table entry is as follows:
  1158. ;
  1159. ;    db    <selector>,"string",<term>
  1160. ;
  1161. ; where:
  1162. ;       <selector> is 8-bit byte that is compared with AH. If it
  1163. ;                   matches, then this string is printed.
  1164. ;
  1165. ;       "string" is the string to be printed
  1166. ;
  1167. ;       <term> is the terminating character, as follows:
  1168. ;
  1169. ;               00H : end of this string
  1170. ;               80H : end of this string, and end of table too
  1171. ;
  1172. ; If no <selector> matches AH, then "????" is printed.
  1173. ;
  1174. ;********************************************************************
  1175.  
  1176. table_print proc near
  1177.     push    si
  1178.     push    dx
  1179.     push    cx
  1180.     push    bx
  1181.     push    ax
  1182.         mov    si,dx            ;use DS:SI to read table
  1183.         cld                ;forward!!!
  1184.  
  1185. table_print2:
  1186.         lodsb                ;get next selector
  1187.         cmp    al,ah            ;does it match AH?
  1188.         jnz    table_print5        ;no, skip to next one
  1189.  
  1190. table_print3:
  1191.  
  1192. ;
  1193. ; We have found string to print. Output it until a terminator is found.
  1194. ;
  1195.  
  1196.         lodsb                ;get byte of string
  1197.         test    al,07fh            ;terminator?
  1198.         jz    table_print9        ;yes, exit
  1199.         call    print            ;no, print this char
  1200.         jmp    table_print3
  1201.  
  1202. table_print5:
  1203.  
  1204. ;
  1205. ; Not this selector. Skip over string till terminator, then go peek
  1206. ; at next selector.
  1207. ;
  1208.  
  1209.         lodsb                ;get byte of string
  1210.         test    al,07fh            ;terminator?
  1211.         jnz    table_print5        ;no, keep skipping
  1212.  
  1213. ;
  1214. ; We have terminator at end of skipped string. It may be end of whole table...
  1215. ;
  1216.  
  1217.         cmp    al,080h            ;end of table?
  1218.         jnz    table_print2        ;no, go check next selector
  1219.         mov    dx,offset huh        ;yes, print "????" message cause match not found
  1220.         call    print_line
  1221.  
  1222. table_print9:
  1223.     pop    ax
  1224.     pop    bx
  1225.     pop    cx
  1226.     pop    dx
  1227.     pop    si
  1228.         ret
  1229. table_print endp
  1230.  
  1231. huh    db    "????$"
  1232.  
  1233. ;*********************************************
  1234. ;
  1235. ; Issue extra linefeeds if we're going to the printer. This
  1236. ; moves the paper up enough to be read.
  1237. ;
  1238. ; This should be called before any input, and whenever output is
  1239. ; generally finished.
  1240. ;
  1241. ;*********************************************
  1242.  
  1243. feed    proc    near
  1244.     push    ax
  1245.     push    cx
  1246.     test    prt_flag,0ffh    ;are we going to the printer?
  1247.     jz    feed9        ;no, just exit
  1248.     mov    cx,num_feeds    ;# linefeeds to do
  1249.     jcxz    feed9        ;none, so exit
  1250.  
  1251. feed2:
  1252.     call    crlf
  1253.     loop    feed2
  1254.  
  1255. feed9:
  1256.     pop    cx
  1257.     pop    ax
  1258.     ret
  1259. feed    endp
  1260.  
  1261.     subttl    Menu Handling
  1262.     page
  1263. ;*********************************************
  1264. ;
  1265. ; Get uppercase keyboard char to AL. AH is clobbered.
  1266. ;
  1267. ;*********************************************
  1268.  
  1269. key    proc    near
  1270.     mov    ah,0        ;use ROM BIOS to read keyboard
  1271.     int    016h
  1272.     cmp    al,'a'        ;lowercase char?
  1273.     jb    key9        ;no
  1274.     cmp    al,'z'
  1275.     ja    key9        ;likewise no
  1276.     and    al,0dfh        ;yes, convert to uppercase
  1277. key9:
  1278.     ret
  1279. key    endp
  1280.  
  1281.  
  1282. ;*********************************************
  1283. ;
  1284. ; Reset all ICT hits to zero, and restart trace buffer
  1285. ;
  1286. ;*********************************************
  1287.  
  1288. zap_hits proc    near
  1289.     push    si
  1290.     push    ax
  1291.     push    bx
  1292.     push    cx
  1293.     mov    cx,8            ;Number of ICT's
  1294.     xor    si,si            ;start with # 0
  1295.     cli                ;no interrupts!
  1296.  
  1297. zap_hits2:
  1298.     mov    bx,ict_index[si]    ;[BX] --> ICT
  1299.     mov    [bx].ICT_hits,0
  1300.     add    si,2            ;up to next ICT
  1301.     loop    zap_hits2        ;till we've done all of them
  1302.  
  1303.     mov    next_byte,offset trace_table
  1304.     sti                ;interrupts OK now
  1305.     pop    cx
  1306.     pop    bx
  1307.     pop    ax
  1308.     pop    si
  1309.     ret
  1310. zap_hits endp
  1311.     page
  1312. ;*********************************************
  1313. ;
  1314. ; Handle main menu selection whose ASCII keypress is in AL.
  1315. ;
  1316. ; Returns: CARRY SET if we should loop back to main menu.
  1317. ;          CARRY CLEAR to exit.
  1318. ;
  1319. ;*********************************************
  1320.  
  1321. do_main proc    near
  1322.     push    ax
  1323.     cmp    al,'P'        ;select printer?
  1324.     jnz    do_main1    ;no
  1325.     call    selprint    ;yes, do it
  1326.     stc            ;"Loop back to main menu" flag
  1327.     jmp    short do_main9
  1328.  
  1329. do_main1:
  1330.     cmp    al,'S'        ;select screen?
  1331.     jnz    do_main2    ;no
  1332.     call    selvideo    ;yes, do it
  1333.     stc            ;"Loop back to main menu" flag
  1334.     jmp    short do_main9
  1335.  
  1336. do_main2:
  1337.     cmp    al,'T'        ;Dump Traces?
  1338.     jnz    do_main3    ;no
  1339.     call    do_traces    ;yes, do it
  1340.     stc            ;"Loop back to main menu" flag
  1341.     jmp    short do_main9
  1342.  
  1343. do_main3:
  1344.     cmp    al,'E'        ;Enable ICT?
  1345.     jnz    do_main4    ;no
  1346.     mov    al,F_ENABLE    ;yes, get bit value to set/clear
  1347.  
  1348. do_main3b:
  1349.     call    do_enable    ;enable/disable F_ENABLE per AL
  1350.     stc            ;"Loop back to main menu" flag
  1351.     jmp    short do_main9
  1352.  
  1353. do_main4:
  1354.     cmp    al,'D'        ;Disable ICT?
  1355.     jnz    do_main5    ;no
  1356.     mov    al,0        ;yes, get bit value to set/clear
  1357.     jmp    do_main3b
  1358.  
  1359. do_main5:
  1360.     cmp    al,'L'        ;List ICT's?
  1361.     jnz    do_main6    ;no
  1362.     call    disp_active    ;yes, do it
  1363.     stc            ;"Loop back to main menu" flag
  1364.     jmp    short do_main9
  1365.  
  1366. do_main6:
  1367.     cmp    al,'C'        ;Clear trace table?
  1368.     jnz    do_main7    ;no
  1369.     call    zap_hits    ;yes, do it
  1370.     stc            ;"Loop back to main menu" flag
  1371.     jmp    short do_main9
  1372.  
  1373. do_main7:
  1374.     cmp    al,'Q'        ;Quit?
  1375.     jnz    do_main8    ;no
  1376.     clc            ;"Exit" flag
  1377.     jmp    short do_main9
  1378.  
  1379. do_main8:
  1380.     cmp    al,'F'        ;F_FCB toggle?
  1381.     jnz    do_main8B    ;no
  1382.     call    do_fcb        ;yes, toggle something
  1383.     stc            ;"Loop back to main menu" flag
  1384.     jmp    short do_main9
  1385.  
  1386. do_main8b:
  1387.  
  1388. ; ------ Unknown selection
  1389.  
  1390.     stc            ;"Loop back to main menu" flag
  1391.  
  1392. do_main9:
  1393.     pop    ax
  1394.     ret
  1395. do_main    endp
  1396.  
  1397.  
  1398. ;**********************************************
  1399. ;
  1400. ; Pick ICT's with which to do something.
  1401. ;
  1402. ; This is called to select ICT for various operations.
  1403. ;
  1404. ; On entry, DX holds address of question (no CRLF's) to be asked.
  1405. ;
  1406. ; Returns: CARRY SET if user selected ABORT to cancel the caller's operation
  1407. ;
  1408. ;          CARRY CLEAR if AL has been set to 8-bit pattern, with each
  1409. ;          bit from 0 to 7 representing an ICT (0-7) that was selected.
  1410. ;
  1411. ;**********************************************
  1412.  
  1413. pick_ict proc    near
  1414.     push    bx
  1415.     push    cx
  1416.     push    dx
  1417.     mov    byte ptr pick_map,0    ;init to nobody selected
  1418.  
  1419. pick_ict1:
  1420.  
  1421. ;
  1422. ; Put up our selection menu
  1423. ;
  1424.  
  1425.     call    crlf
  1426.     pop    dx            ;display caller's question
  1427.     push    dx
  1428.     call    print_line
  1429.     mov    dx,offset pick_menu    ;put up our menu
  1430.     call    print_line
  1431.  
  1432. ;
  1433. ; Fill in choices already made, as if he had typed them
  1434. ;
  1435.  
  1436.     mov    cx,8            ;# ICT's
  1437.     mov    ah,byte ptr pick_map    ;AH has bitmap
  1438.     mov    al,'0'            ;AL holds ASCII '0' - '7'
  1439.  
  1440. pick_ict1b:
  1441.     test    ah,1            ;Is this ICT selected?
  1442.     jz    pick_ict1c        ;no
  1443.     call    print            ;yes, show corresponding ASCII char
  1444.  
  1445. pick_ict1c:
  1446.     inc    al            ;Bump ASCII char
  1447.     shr    ah,1            ;get next bit to test
  1448.     loop    pick_ict1b        ;till done all 8
  1449.     call    feed            ;eject paper on printer
  1450.  
  1451. pick_ict2:
  1452.  
  1453. ;
  1454. ; Get and handle next keypress
  1455. ;
  1456.  
  1457.     call    key
  1458.     cmp    al,'0'            ;ICT number?
  1459.     jb    pick_ict3        ;no
  1460.     cmp    al,'7'
  1461.     ja    pick_ict3        ;no
  1462.     call    print            ;yes, echo it
  1463.  
  1464. ;
  1465. ; Convert this ASCII char to bitmap bit, and add to our map
  1466. ;
  1467.  
  1468.     call    bin_to_bit        ;comes back in AL
  1469.     or    byte ptr pick_map,al    ;add this new bit into pattern
  1470.     jmp    pick_ict2        ;go get next keypress
  1471.  
  1472. pick_ict3:
  1473.     cmp    al,'L'            ;List ICT's?
  1474.     jnz    pick_ict4        ;no
  1475.     call    disp_active        ;yes, show all active ICT's
  1476.     jmp    pick_ict1        ;give our menu again
  1477.  
  1478. pick_ict4:
  1479.     cmp    al,'R'            ;Restart?
  1480.     jnz    pick_ict5        ;no
  1481.     mov    byte ptr pick_map,0    ;yes, clear map
  1482.     jmp    pick_ict1        ;give new menu
  1483.  
  1484. pick_ict5:
  1485.     cmp    al,'G'            ;Go with choices?
  1486.     jnz    pick_ict6        ;no
  1487.  
  1488. pick_ict5b:
  1489.     mov    al,byte ptr pick_map    ;yes, get choices as bitmap
  1490.     clc                ;tell caller to use it
  1491.     jmp    short pick_ict9        ;exit
  1492.  
  1493. pick_ict6:
  1494.     cmp    al,0dh            ;Carriage Return?
  1495.     jz    pick_ict5b        ;yes, same as "Go"
  1496.     cmp    al,'A'            ;Abort operation?
  1497.     jnz    pick_ict7        ;no
  1498.  
  1499. pick_ict6b:
  1500.     stc                ;tell caller to abort
  1501.     jmp    short pick_ict9        ;exit
  1502.  
  1503. pick_ict7:
  1504.     cmp    al,1bh            ;ESCAPE?
  1505.     jz    pick_ict6b        ;yes, same as "Abort"
  1506.  
  1507. ; ------ Unknown choice
  1508.  
  1509.     jmp    pick_ict2        ;go get next keypress
  1510.  
  1511. pick_ict9:
  1512.     pop    dx
  1513.     pop    cx
  1514.     pop    bx
  1515.     ret
  1516. pick_ict endp
  1517.  
  1518. pick_menu    db    0dh,0ah
  1519.         db    "0-7 picks ICT   (L)ist ICT's  (A)bort  (R)estart  (G)o with choices"
  1520.         db    0dh,0ah,":$"
  1521.  
  1522. pick_map    db    0    ;bitmap of selected ICT's
  1523.  
  1524.  
  1525. ;*********************************************
  1526. ;
  1527. ; Handle "Traces" main menu option
  1528. ;
  1529. ;*********************************************
  1530.  
  1531. do_traces proc    near
  1532.     push    ax
  1533.     push    dx
  1534.     mov    dx,offset trace_menu    ;put up our menu
  1535.     call    print_line
  1536.     call    feed            ;extra CRLF's for printer
  1537.     call    key            ;get his selection
  1538.     cmp    al,'A'            ;dump All?
  1539.     jnz    do_traces2        ;no
  1540.     mov    al,0ffh            ;yes, get bitmap for all ICT's
  1541.     jmp    short do_traces7    ;dump 'em
  1542.  
  1543. do_traces2:
  1544.     cmp    al,'S'            ;Selected ICT's?
  1545.     jnz    do_traces9        ;no, so exit
  1546.     mov    dx,offset trace_prompt    ;point to question to be used
  1547.     call    pick_ict        ;get ICT's as bitmap in AL
  1548.     jc    do_traces9        ;user wants to forget about it
  1549.  
  1550. do_traces7:
  1551.  
  1552. ;
  1553. ; Do dump, with AL holding bitmap of ICT's that are to be included
  1554. ;
  1555.  
  1556.     call    dump_buf        ;with AL already set
  1557.  
  1558. do_traces9:
  1559.     pop    dx
  1560.     pop    ax
  1561.     ret
  1562. do_traces endp
  1563.  
  1564. trace_menu    db    0dh,0ah
  1565.         db    "Display (A)ll or (S)elected ICTs' traces:$"
  1566. trace_prompt    db    "Pick ICT's whose traces are to be included in dump$"
  1567.  
  1568.  
  1569. ;*********************************************
  1570. ;
  1571. ; Set or Clear F_ENABLE.
  1572. ;
  1573. ; On entry, AL holds bit value for F_ENABLE (i.e. - ON or OFF).
  1574. ;
  1575. ; This routine asks user for ICT's to be enabled or disabled.
  1576. ;
  1577. ;*********************************************
  1578.  
  1579. do_enable proc    near
  1580.     push    si
  1581.     push    dx
  1582.     push    cx
  1583.     push    bx
  1584.     push    ax            ;push him last so we can get to him
  1585.  
  1586.     mov    dx,offset enable_prompt    ;Assume "Enable"
  1587.     test    al,F_ENABLE        ;are we enabling?
  1588.     jnz    do_enable1        ;yes, we have right message
  1589.     mov    dx,offset disable_prompt ;Use "Disable" message
  1590.  
  1591. do_enable1:
  1592.     call    pick_ict        ;get ICT's to be affected
  1593.     jc    do_enable9        ;user wants to forget it
  1594.     mov    byte ptr enable_map,al    ;save bitmap of ICT's to be done
  1595.     xor    si,si            ;start with ICT #0
  1596.     mov    cx,8            ;number of ICT's to look at
  1597.  
  1598. do_enable2:
  1599.     test    byte ptr enable_map,1    ;Should this ICT be done?
  1600.     jz    do_enable5        ;no
  1601.     mov    bx,ict_index[si]    ;yes, point to ICT
  1602.     cli                ;*** NO INTERRUPTS!!! ***
  1603.     pop    ax            ;get F_ENABLE value
  1604.     push    ax
  1605.     and    al,F_ENABLE        ;isolate our bit
  1606.     mov    ah,[bx].ICT_flags    ;get current flags value
  1607.     and    ah,F_ENABLE XOR 0ffh    ;turn off our bit
  1608.     or    ah,al            ;set it per caller's desire
  1609.     mov    [bx].ICT_flags,ah    ;replace it in ICT
  1610.     STI                ;*** INTERRUPTS OK NOW ***
  1611.  
  1612. do_enable5:
  1613.     add    si,2            ;up to next ICT
  1614.     shr    byte ptr enable_map,1    ;get next ICT's bitmap bit to Bit 0
  1615.     loop    do_enable2        ;till we've looked at all ICT's
  1616.  
  1617. do_enable9:
  1618.     pop    ax
  1619.     pop    bx
  1620.     pop    cx
  1621.     pop    dx
  1622.     pop    si
  1623.     ret
  1624. do_enable endp
  1625.  
  1626. enable_prompt    db    "Pick ICT's to have tracing ENABLED$"
  1627. disable_prompt    db    "Pick ICT's to have tracing DISABLED$"
  1628. enable_map    db    0        ;bitmap of ICT's to be altered
  1629.  
  1630.  
  1631.  
  1632.  
  1633. ;*********************************************
  1634. ;
  1635. ; Toggle F_FCB in some ICT's.
  1636. ;
  1637. ;*********************************************
  1638.  
  1639. do_fcb proc    near
  1640.     push    si
  1641.     push    dx
  1642.     push    cx
  1643.     push    bx
  1644.     push    ax            ;push him last so we can get to him
  1645.  
  1646.     mov    dx,offset fcb_toggle
  1647.     call    pick_ict        ;get ICT's to be affected
  1648.     jc    do_fcb9            ;user wants to forget it
  1649.     xor    si,si            ;start with ICT #0
  1650.     mov    cx,8            ;number of ICT's to look at
  1651.  
  1652. do_fcb2:
  1653.     test    al,1            ;Should this ICT be done?
  1654.     jz    do_fcb5            ;no
  1655.     mov    bx,ict_index[si]    ;yes, point to ICT
  1656.     xor    [bx].ICT_flags,F_FCB    ;toggle current setting
  1657.  
  1658. do_fcb5:
  1659.     add    si,2            ;up to next ICT
  1660.     shr    al,1            ;get next ICT's bitmap bit to Bit 0
  1661.     loop    do_fcb2            ;till we've looked at all ICT's
  1662.  
  1663. do_fcb9:
  1664.     pop    ax
  1665.     pop    bx
  1666.     pop    cx
  1667.     pop    dx
  1668.     pop    si
  1669.     ret
  1670. do_fcb endp
  1671.  
  1672. fcb_toggle    db    "Pick ICT's to have F_FCB toggled$"
  1673.  
  1674.     subttl    Reporting Routines
  1675.     page
  1676. ;**************************************************
  1677. ;
  1678. ; Dump trace buffer for ICT's represented by bitmap in AL.
  1679. ;
  1680. ; If bit n in AL is set, then ICT n's trace records are to be included
  1681. ; in dump.
  1682. ;
  1683. ;**************************************************
  1684.  
  1685.  
  1686. dump_buf proc    near
  1687.     push    di
  1688.     push    si
  1689.     push    dx
  1690.     push    cx
  1691.     push    bx
  1692.     push    ax            ;push bitmap last so that we can get to it
  1693.     xor    di,di            ;di is printed line counter
  1694.     mov    si,offset trace_table   ;start at front of buf
  1695.  
  1696. dump_buf2:
  1697.     cmp    si,next_byte        ;done whole buffer?
  1698.     jae    dump_buf9        ;yes, exit
  1699.  
  1700. ;
  1701. ; Let a keypress interrupt us
  1702. ;
  1703.  
  1704.     mov    ah,1            ;ROM BIOS "Check for keypress" func
  1705.     int    016h            ;keypress present?
  1706.     jnz    dump_buf9        ;yes, exit
  1707.  
  1708.     mov    al,[si].B_type        ;get ICT #
  1709.     call    bin_to_bit        ;convert to bitmap bit
  1710.     pop    bx            ;peek at caller's requested bitmap
  1711.     push    bx
  1712.     and    bl,al            ;is this ICT included in caller's bitmap?
  1713.     jz    dump_buf5        ;no, skip it
  1714.  
  1715. ;
  1716. ; See if it's time for title line
  1717. ;
  1718.  
  1719.     test    di,07h            ;every 8 lines
  1720.     jnz    dump_buf4        ;not time for title line
  1721.     mov    dx,offset dump_title    ;print title line
  1722.     call    print_line
  1723.  
  1724. dump_buf4:
  1725.     call    dump_rec        ;dump this record
  1726.     inc    di            ;bump # lines printed
  1727.  
  1728. dump_buf5:
  1729.  
  1730. ;
  1731. ; Skip over this record, to next one. To do that, we need to know what
  1732. ; type of record it is, so that we know how big a record
  1733. ; we have to skip over.
  1734. ;
  1735.  
  1736.     mov    bl,[si].B_type        ;get trace record type
  1737.     and    bx,11110000b        ;isolate type itself
  1738.     shr    bx,1            ;develop type times 2
  1739.     shr    bx,1
  1740.     shr    bx,1
  1741.     add    si,rec_sizes[bx]    ;add record size to current pointer
  1742.     jmp    dump_buf2        ;continue till buffer exhausted
  1743.  
  1744. dump_buf9:
  1745.     pop    ax
  1746.     pop    bx
  1747.     pop    cx
  1748.     pop    dx
  1749.     pop    si
  1750.     pop    di
  1751.     ret
  1752. dump_buf endp
  1753.  
  1754. dump_title    db    0dh,0ah
  1755.         db    0dh,0ah
  1756.         db    "INT #   AX   BX   CX   DX   ES   DS   SI   DI   BP   SS   SP   CS:IP"
  1757.         db    0dh,0ah
  1758.         db    "--- -   ---- ---- ---- ---- ---- ---- ---- ---- ---- ---- ---- ---------$"
  1759.  
  1760. ;***********************************************
  1761. ;
  1762. ; Given binary number (0-7) in AL, return bitmap in AL with corresponding
  1763. ; bit (Bit 0 thru Bit 7) set.
  1764. ;
  1765. ; AH is zeroed.
  1766. ;
  1767. ;***********************************************
  1768.  
  1769. bin_to_bit proc    near
  1770.     mov    ah,al        ;AH is counter, from 7 to 0
  1771.     mov    al,1        ;AL is bitmap, Bit 0 to Bit 7
  1772.     and    ah,7        ;constrain input
  1773.     jz    bin_to_bit9    ;binary was 0, so return with Bit 0 set
  1774.  
  1775. bin_to_bit3:
  1776.     add    al,al        ;shift bitmap left 1 bit
  1777.     dec    ah        ;dec count by one
  1778.     jnz    bin_to_bit3
  1779.  
  1780. bin_to_bit9:
  1781.     ret
  1782. bin_to_bit endp
  1783.  
  1784. ;***********************************************
  1785. ;
  1786. ; Dump trace record at [SI]. This routine prints the common
  1787. ; header information, then calls specific routines to expand
  1788. ; details.
  1789. ;
  1790. ;***********************************************
  1791.  
  1792. dump_rec proc    near
  1793.     push    si
  1794.     push    dx
  1795.     push    cx
  1796.     push    bx
  1797.     push    ax
  1798.  
  1799.     call    crlf
  1800.     mov    al,[si].B_int        ;get Interrupt #
  1801.     call    print_hex        ;show interrupt #
  1802.     mov    al,'H'
  1803.     call    print
  1804.     mov    al,' '
  1805.     call    print
  1806.     mov    al,[si].B_type        ;get ICT #
  1807.     and    al,7
  1808.     or    al,'0'            ;make into ASCII digit
  1809.     call    print
  1810.     mov    al,' '
  1811.     call    print
  1812.     mov    bl,[si].B_type        ;get trace type
  1813.     and    bx,11110000b        ;isolate type of trace
  1814.     shr    bx,1            ;develop type times 2
  1815.     shr    bx,1
  1816.     shr    bx,1
  1817.     mov    bx,word ptr dump_table[bx]
  1818.     call    bx            ;call proper specific routine
  1819.     pop    ax
  1820.     pop    bx
  1821.     pop    cx
  1822.     pop    dx
  1823.     pop    si
  1824.     ret
  1825. dump_rec endp
  1826.  
  1827. ;
  1828. ; Table of routines to handle various record types
  1829. ;
  1830.  
  1831. dump_table    label    word
  1832.         dw    offset dump_before    ;record type 0 = BEFORE
  1833.         dw    offset dump_after    ;record type 1 = AFTER
  1834.         dw    offset dump_fcb        ;record type 2 = FCB
  1835.         dw    offset dump_asciiz    ;record type 3 = ASCIIZ
  1836.  
  1837. ;***********************************************
  1838. ;
  1839. ; Dump BEFORE record at [SI]
  1840. ;
  1841. ;***********************************************
  1842.  
  1843. dump_before proc near
  1844.     push    si
  1845.     push    dx
  1846.     push    cx
  1847.     push    bx
  1848.     push    ax
  1849.     mov    al,'B'            ;Display "B" for BEFORE
  1850.     call    print
  1851.     mov    al,' '            ;plus blank after
  1852.     call    print
  1853.     mov    ax,[si].B_ax
  1854.     call    print_wordb
  1855.     mov    ax,[si].B_bx
  1856.     call    print_wordb
  1857.     mov    ax,[si].B_cx
  1858.     call    print_wordb
  1859.     mov    ax,[si].B_dx
  1860.     call    print_wordb
  1861.     mov    ax,[si].B_es
  1862.     call    print_wordb
  1863.     mov    ax,[si].B_ds
  1864.     call    print_wordb
  1865.     mov    ax,[si].B_si
  1866.     call    print_wordb
  1867.     mov    ax,[si].B_di
  1868.     call    print_wordb
  1869.     mov    ax,[si].B_bp
  1870.     call    print_wordb
  1871.     mov    ax,[si].B_ss
  1872.     call    print_wordb
  1873.     mov    ax,[si].B_sp
  1874.     call    print_wordb
  1875.     mov    dx,[si].B_cs
  1876.     mov    ax,[si].B_ip
  1877.     call    print_seg
  1878.  
  1879. ;
  1880. ; Try to interpret this BEFORE record, to make reading easier
  1881. ;
  1882.  
  1883.     call    interp
  1884.     pop    ax
  1885.     pop    bx
  1886.     pop    cx
  1887.     pop    dx
  1888.     pop    si
  1889.     ret
  1890. dump_before endp
  1891.  
  1892. ;***********************************************
  1893. ;
  1894. ; Dump AFTER record at [SI]
  1895. ;
  1896. ;***********************************************
  1897.  
  1898. dump_after proc near
  1899.     push    si
  1900.     push    dx
  1901.     push    cx
  1902.     push    bx
  1903.     push    ax
  1904.     mov    al,'A'            ;Display "A" for AFTER
  1905.     call    print
  1906.     mov    al,' '            ;plus blank after
  1907.     call    print
  1908.     mov    ax,[si].A_ax
  1909.     call    print_wordb
  1910.     mov    ax,[si].A_bx
  1911.     call    print_wordb
  1912.     mov    ax,[si].A_cx
  1913.     call    print_wordb
  1914.     mov    ax,[si].A_dx
  1915.     call    print_wordb
  1916.     mov    ax,[si].A_es
  1917.     call    print_wordb
  1918.     mov    ax,[si].A_ds
  1919.     call    print_wordb
  1920.     mov    ax,[si].A_si
  1921.     call    print_wordb
  1922.     mov    ax,[si].A_di
  1923.     call    print_wordb
  1924.     mov    ax,[si].A_bp
  1925.     call    print_wordb
  1926.  
  1927. ;
  1928. ; Now expand flags byte for clarity
  1929. ;
  1930.  
  1931.     mov    dx,[si].A_flags        ;hold flags in DX
  1932.     mov    si,offset dump_flags    ;SI = next flag's name
  1933.     mov    bx,0fd5h        ;mask of valid bits in flags word
  1934.     mov    cx,12            ;# bits to walk through
  1935.     cld                ;forward!!!
  1936.  
  1937. dump_after2:
  1938.     test    bx,1            ;is this a valid flag bit?
  1939.     jz    dump_after4        ;no, move to next one
  1940.     lodsb                ;yes, get next name
  1941.     test    dx,1            ;is bit set?
  1942.     jnz    dump_after3        ;yes, use name
  1943.     mov    al,' '            ;no, use blank
  1944.  
  1945. dump_after3:
  1946.     call    print            ;print flag name or space
  1947.  
  1948. dump_after4:
  1949.     shr    dx,1            ;shift flags so next flag is in bit 0
  1950.     shr    bx,1            ;ditto for mask
  1951.     loop    dump_after2        ;till done all 12 bits
  1952.  
  1953.     pop    ax
  1954.     pop    bx
  1955.     pop    cx
  1956.     pop    dx
  1957.     pop    si
  1958.     ret
  1959. dump_after endp
  1960.  
  1961. dump_flags    db    "CPAZSTIDO"
  1962.  
  1963.  
  1964. ;***********************************************
  1965. ;
  1966. ; Dump FCB record at [SI]
  1967. ;
  1968. ;***********************************************
  1969.  
  1970. dump_fcb proc near
  1971.     push    si
  1972.     push    dx
  1973.     push    cx
  1974.     push    bx
  1975.     push    ax
  1976.     mov    al,[si].FCB_drive    ;display drive # as number
  1977.     mov    byte ptr fcb_drv,al
  1978.     mov    dx,offset fcb_line    ;and put up rest of header
  1979.     call    print_edit
  1980.     add    si,3            ;skip to filename field
  1981.     mov    cx,8            ;max # chars to display
  1982.     cld                ;forward!!!
  1983.  
  1984. dump_fcb2:
  1985.     lodsb                ;get byte of filename
  1986.     cmp    al,020h            ;control char or blank?
  1987.     jbe    dump_fcb3b        ;yes, we're done with name
  1988.     call    print            ;no, display char as-is
  1989.     loop    dump_fcb2        ;till 8 done or early exit
  1990.     jmp    short dump_fcb4
  1991.  
  1992. dump_fcb3:                ;skip over rest of filename
  1993.     lodsb
  1994.  
  1995. dump_fcb3b:
  1996.     loop    dump_fcb3
  1997.  
  1998. dump_fcb4:                ;output extension too
  1999.     mov    al,'.'            ;seperate it with period
  2000.     call    print
  2001.     mov    cx,3            ;# extension bytes to print
  2002.  
  2003. dump_fcb5:
  2004.     lodsb                ;get byte of extension
  2005.     cmp    al,020h            ;control char?
  2006.     jb    dump_fcb6        ;yes, skip it
  2007.     call    print            ;no, use as-is
  2008.  
  2009. dump_fcb6:
  2010.     loop    dump_fcb5
  2011.     pop    ax
  2012.     pop    bx
  2013.     pop    cx
  2014.     pop    dx
  2015.     pop    si
  2016.     ret
  2017. dump_fcb endp
  2018.  
  2019.  
  2020. fcb_line    label    byte
  2021.         db    "FCB Drive:"
  2022.         db    Edit_Dec8
  2023. fcb_drv        db    0
  2024.         db    " Filename: "
  2025.         db    Edit_End
  2026.  
  2027. ;***********************************************
  2028. ;
  2029. ; Dump ASCIIZ record at [SI]
  2030. ;
  2031. ;***********************************************
  2032.  
  2033. dump_asciiz proc near
  2034.     push    si
  2035.     push    dx
  2036.     push    cx
  2037.     push    bx
  2038.     push    ax
  2039.     mov    dx,offset asciiz_line    ;put up header
  2040.     call    print_line
  2041.     add    si,2            ;skip to start of ASCIIZ text
  2042.     mov    cx,size ASCIIZ        ;max # chars to display
  2043.     sub    cx,2            ;(minus 2 for header)
  2044.     cld                ;forward!!!
  2045.  
  2046. dump_asciiz5:
  2047.     lodsb                ;get byte of extension
  2048.     or    al,al            ;NUL terminator?
  2049.     jz    dump_asciiz9        ;yes, exit
  2050.     cmp    al,020h            ;control char?
  2051.     jb    dump_asciiz6        ;yes, skip it
  2052.     call    print            ;no, use as-is
  2053.  
  2054. dump_asciiz6:
  2055.     loop    dump_asciiz5
  2056.  
  2057. dump_asciiz9:
  2058.     pop    ax
  2059.     pop    bx
  2060.     pop    cx
  2061.     pop    dx
  2062.     pop    si
  2063.     ret
  2064. dump_asciiz endp
  2065.  
  2066.  
  2067. asciiz_line    label    byte
  2068.         db    "ASCIIZ: $"
  2069.  
  2070.  
  2071. ;*****************************************
  2072. ;
  2073. ; Display what we know about ICT # AL (0-7).
  2074. ;
  2075. ;*****************************************
  2076.  
  2077. ict_dump proc    near
  2078.     push    dx
  2079.     push    bx
  2080.     push    ax
  2081.  
  2082.     and    ax,7            ;edit ICT #
  2083.     mov    bx,ax            ;get ICT #
  2084.     shl    bx,1
  2085.     mov    bx,ict_index[bx]    ;[BX] --> ICT itself
  2086.  
  2087.     or    al,030h            ;make ASCII digit for message
  2088.     mov    byte ptr ict_msg1a,al    ;insert it into message
  2089.     mov    dx,offset ict_msg1      ;"ICT #n at ..."
  2090.     call    print_line
  2091.  
  2092.     mov    dx,ds            ;display seg:offset of ICT
  2093.     mov    ax,bx
  2094.     call    print_seg
  2095.  
  2096.     mov    dx,offset ict_ena    ;show whether enabled or disabled
  2097.     test    [bx].ICT_flags,F_ENABLE
  2098.     jnz    ict_dump2        ;got right message
  2099.     mov    dx,offset ict_dis    ;get other message
  2100.  
  2101. ict_dump2:
  2102.     call    print_line        ;display "ENABLED" or "DISABLED"
  2103.  
  2104.     mov    dx,offset ict_msg2      ;"INT xxH "
  2105.     call    print_line
  2106.     mov    al,[bx].ICT_intnum    ;display interrupt #
  2107.     call    print_hex
  2108.  
  2109.     mov    dx,offset ict_msg3      ;"AH range ll/hh"
  2110.     call    print_line
  2111.     mov    al,[bx].ICT_AH_lo    ;display AH range lower limit
  2112.     call    print_hex
  2113.     mov    al,'/'          ;add seperator
  2114.     call    print
  2115.     mov    al,[bx].ICT_AH_hi       ;display AH range upper limit
  2116.     call    print_hex
  2117.  
  2118.     mov    al,'*'            ;display '*' if FCB/ASCIIZ set
  2119.     test    [bx].ICT_flags,F_FCB
  2120.     jnz    ict_dump3        ;it's set
  2121.     mov    al,' '            ;not set, so use blank
  2122.  
  2123. ict_dump3:
  2124.     call    print
  2125.  
  2126.     mov    dx,offset ict_msg4      ;"Exit: RET/RET2/IRET"
  2127.     call    print_line
  2128.     mov    al,[bx].ICT_flags    ;interpret exit type
  2129.     mov    dx,offset ict_exit    ;get to first 6-char message
  2130.     test    al,F_RET
  2131.     jz    ict_dump5        ;not this one
  2132.     call    print_line
  2133.  
  2134. ict_dump5:
  2135.     add    dx,6            ;up to next 6-char exit name
  2136.     test    al,F_RET2
  2137.     jz    ict_dump6        ;not this one
  2138.     call    print_line
  2139.  
  2140. ict_dump6:
  2141.     add    dx,6            ;up to next 6-char exit name
  2142.     test    al,F_IRET
  2143.     jz    ict_dump7        ;not this one
  2144.     call    print_line
  2145.  
  2146. ict_dump7:
  2147.     mov    dx,offset ict_msg4a    ;"Hits: "
  2148.     call    print_line
  2149.     mov    ax,[bx].ICT_hits
  2150.     call    print_dec
  2151.  
  2152.     pop    ax
  2153.     pop    bx
  2154.     pop    dx
  2155.     ret
  2156.  
  2157. ict_msg1    db    0dh,0ah,"ICT#"
  2158. ict_msg1a    db    "0 @ $"
  2159. ict_msg2    db    " INT $"
  2160. ict_msg3    db    "H AH:$"
  2161. ict_msg4    db    " Exit:$"
  2162. ict_msg4a    db    "Hits: $"
  2163. ict_exit    db    "RET  $"    ;6-char exit type names
  2164.         db    "RET2 $"
  2165.         db    "IRET $"
  2166. ict_ena        db    " ENABLED $"
  2167. ict_dis        db    " DISABLED$"
  2168.  
  2169. ict_dump endp
  2170.  
  2171.  
  2172. ;*********************************************
  2173. ;
  2174. ; Display all active ICT's
  2175. ;
  2176. ;*********************************************
  2177.  
  2178. disp_active    proc    near
  2179.     push    si
  2180.     push    ax
  2181.     push    bx
  2182.     push    cx
  2183.  
  2184.     mov    cx,8            ;Number of ICT's
  2185.     xor    si,si            ;start with # 0
  2186.  
  2187. disp_active2:
  2188.     mov    bx,ict_index[si]    ;[BX] --> ICT
  2189.     test    [bx].ICT_flags,F_ACTIVE    ;Is this ICT active?
  2190.     jz    disp_active5        ;no, skip it
  2191.     mov    ax,si            ;yes, develop ICT # 0-7
  2192.     shr    ax,1
  2193.     call    ict_dump        ;display it
  2194.  
  2195. disp_active5:
  2196.     add    si,2            ;up to next ICT
  2197.     loop    disp_active2        ;till we've done all of them
  2198.     pop    cx
  2199.     pop    bx
  2200.     pop    ax
  2201.     pop    si
  2202.     ret
  2203. disp_active endp
  2204.  
  2205.     subttl    Interpretation - Misc Routines
  2206.     page
  2207. ;********************************************************************
  2208. ;*                                                                  *
  2209. ;*  This file contains the routines that interpret selected         *
  2210. ;*  BEFORE trace records and print out sensible summaries of        *
  2211. ;*  their meanings. This sure beats having to read a lotta hex      *
  2212. ;*  function codes.                                                 *
  2213. ;*                                                                  *
  2214. ;*  The main routine - interp() - is called just after we've        *
  2215. ;*  printed all of the trace record in hex. If this record is       *
  2216. ;*  one that we know about, we should now print a one-line          *
  2217. ;*  interpretation of the record. This is done via lower-level      *
  2218. ;*  routines called by interp() per the INT in the record.          *
  2219. ;*                                                                  *
  2220. ;********************************************************************
  2221.  
  2222.  
  2223. ;********************************************************************
  2224. ;
  2225. ; Interpret BEFORE trace record at [SI].
  2226. ;
  2227. ;********************************************************************
  2228.  
  2229. interp    proc    near
  2230.     push    bx
  2231.     push    ax
  2232.     mov    ah,[SI].B_int        ;get INT type
  2233.     mov    bx,offset interp_tab    ;point to table of handlers
  2234.  
  2235. interp2:
  2236.     cmp    ah,[bx]            ;does this handler go with this INT?
  2237.     jnz    interp5            ;no
  2238.     mov    bx,1[bx]        ;yes, get handler's address
  2239.     call    bx            ;call that handler
  2240.     jmp    interp9            ;exit
  2241.  
  2242. interp5:
  2243.     add    bx,3            ;up to next entry in table
  2244.     cmp    bx,offset interp_end    ;searched whole table yet?
  2245.     jb    interp2            ;no, try next one
  2246.  
  2247. interp9:
  2248.  
  2249.     pop    ax
  2250.     pop    bx
  2251.         ret
  2252. interp    endp
  2253.  
  2254. ;
  2255. ; Table of interpreters for various interrupts.
  2256. ;
  2257. ; Each entry is as follows:
  2258. ;
  2259. ;       db    <intnum>        ;interrupt number
  2260. ;       dw    offset <handler>    ;address of handler to interpret this int's record
  2261. ;
  2262. ;
  2263.  
  2264. interp_tab    label    byte
  2265.         db    013h            ;INT 13h is Diskette I/O
  2266.         dw    offset interp_13    ;handler for INT 13h
  2267.         db    021h            ;INT 21h is DOS Function Handler
  2268.         dw    offset interp_21    ;handler for INT 21h
  2269.         db    025h            ;INT 025H is DOS ABSOLUTE DISK READ
  2270.         dw    offset interp_25
  2271.         db    026h            ;INT 026H is DOS ABSOLUTE DISK WRITE
  2272.         dw    offset interp_25    ;uses same interpreter
  2273. interp_end    label    byte            ;end of table
  2274.  
  2275.     subttl    Interpretation - INT 13 (Diskette I/O)
  2276.     page
  2277. ;
  2278. ; Tables used to interpret INT 13h
  2279. ;
  2280.  
  2281. Floppy_or_Hard    db    0,"Floppy:",0
  2282.         db    080h,"Fixed:",080h
  2283.  
  2284. Cyl_or_Track    db    0,"Track:",0
  2285.         db    080h,"Cyl:",080h
  2286.  
  2287. int13_functab    label    byte
  2288.         db    0,"Reset Disk",0
  2289.         db    1,"Read Status",0
  2290.         db    2,"Read to ES:BX",0
  2291.         db    3,"Write from ES:BX",0
  2292.         db    4,"Verify",0
  2293.         db    5,"Format Track per ES:BX",0
  2294.         db    6,"Format & Set Bad Sects",0
  2295.         db    7,"Format Drive from Track",0
  2296.         db    8,"Get Drive Params",0
  2297.         db    9,"Init Drive Params",0
  2298.         db    10,"Read Long",0
  2299.         db    11,"Write Long",0
  2300.         db    12,"Seek",0
  2301.         db    13,"Alt Disk Reset",0
  2302.         db    14,"Read Sect Buf",0
  2303.         db    15,"Write Sect Buf",0
  2304.         db    16,"Test Drive Ready",0
  2305.         db    17,"Recalibrate",0
  2306.         db    18,"Ram Diagnostic",0
  2307.         db    19,"Drive Diagnostic",0
  2308.         db    20,"Internal Diagnostic",0
  2309.         db    21,"Get Disk Type",0
  2310.         db    22,"Change Status",0
  2311.         db    23,"Set Disk Type",080h
  2312.  
  2313. int13_line    label    byte
  2314.         db    0dh,0ah,"      "
  2315.         db    Edit_Call
  2316. int13_F_or_H    db    0
  2317.         dw    offset Floppy_or_Hard
  2318.         dw    offset table_print
  2319.         db    Edit_Dec8
  2320. int13_drive    db    0
  2321.         db    " Head:"
  2322.         db    Edit_Dec8
  2323. int13_head    db    0
  2324.         db    " "
  2325.         db    Edit_Call
  2326. int13_C_or_T    db    0
  2327.         dw    offset Cyl_or_Track
  2328.         dw    offset table_print
  2329.         db    Edit_Dec16
  2330. int13_cyl    dw    0
  2331.         db    " Sect:"
  2332.         db    Edit_Dec8
  2333. int13_sect    db    0
  2334.         db    " #Sects:"
  2335.         db    Edit_Dec8
  2336. int13_numsects    db    0
  2337.         db    " "
  2338.         db    Edit_Call
  2339. int13_func    db    0
  2340.         dw    offset int13_functab
  2341.         dw    offset table_print
  2342.         db    Edit_End
  2343.  
  2344. ;**************************************************
  2345. ;
  2346. ; Interpret INT 13h BEFORE trace record at [SI]
  2347. ;
  2348. ;**************************************************
  2349.  
  2350. interp_13 proc    near
  2351.     push    dx
  2352.     push    cx
  2353.     push    ax
  2354.     mov    dx,[SI].B_dx        ;get DX at time of INT
  2355.     mov    al,dl            ;Get drive #
  2356.     and    al,080h            ;isolate floppy/hard bit
  2357.     mov    int13_F_or_H,al        ;use it to select device name...
  2358.     mov    int13_C_or_T,al        ;...as well as cylinders/tracks
  2359.     and    dl,07fh            ;isolate drive #
  2360.     mov    int13_drive,dl
  2361.     mov    int13_head,dh        ;store head #
  2362.     mov    cx,[SI].B_cx        ;get CX at time of INT
  2363.     xor    ax,ax            ;calc 10-bit cylinder #
  2364.     mov    al,cl
  2365.     shl    ax,1
  2366.     shl    ax,1
  2367.     mov    al,ch
  2368.     mov    int13_cyl,ax        ;save as word
  2369.     and    cl,00111111b        ;isolate sector #
  2370.     mov    int13_sect,cl
  2371.     mov    ax,[SI].B_ax        ;get AX at time of INT
  2372.     mov    int13_numsects,al
  2373.     mov    int13_func,ah
  2374.     mov    dx,offset int13_line    ;now print edited line
  2375.     call    print_edit
  2376.     pop    ax
  2377.     pop    cx
  2378.     pop    dx
  2379.     ret
  2380. interp_13 endp
  2381.  
  2382.     subttl    Interpretation - INT 21h (DOS)
  2383.     page
  2384. ;
  2385. ; Tables used in interpreting INT 21h
  2386. ;
  2387.  
  2388. int21_functab label byte
  2389.     db    0,"Terminate program",0
  2390.     db    1,"Console input w/echo to AL",0
  2391.     db    2,"Display Output of DL",0
  2392.     db    3,"AUX input to AL",0
  2393.     db    4,"AUX output from DL",0
  2394.     db    5,"Printer output from DL",0
  2395.     db    6,"Input to AL (DL=0FFh) or Display DL",0
  2396.     db    7,"Raw keyboard input w/o echo to AL",0
  2397.     db    8,"Console input w/o echo to AL",0
  2398.     db    9,"Print string at DS:DX till '$'",0
  2399.     db    0ah,"Buffered console input to DS:DX",0
  2400.     db    0bh,"Set AL=0FFh if input ready, else AL=0",0
  2401.     db    0ch,"Clear buf and do function in AL",0
  2402.     db    0dh,"Reset disk",0
  2403.     db    0eh,"Select drive per DL (0=A)",0
  2404.     db    0fh,"Open file, FCB at DS:DX",0
  2405.     db    10h,"Close file, FCB at DS:DX",0
  2406.     db    11h,"Search for first per pattern FCB at DS:DX",0
  2407.     db    12h,"Search for next per pattern FCB at DS:DX",0
  2408.     db    13h,"Delete file per FCB at DS:DX",0
  2409.     db    14h,"Read sequential, FCB at DS:DX",0
  2410.     db    15h,"Write sequential, FCB at DS:DX",0
  2411.     db    16h,"Create file, FCB at DS:DX",0
  2412.     db    17h,"Rename file, special FCB at DS:DX",0
  2413.     db    19h,"Return current drive in AL (0=A)",0
  2414.     db    1ah,"Set DTA to DS:DX",0
  2415.     db    1bh,"Get FAT info for default drive",0
  2416.     db    1ch,"Get FAT info for drive DL (0=default)",0
  2417.     db    21h,"Random Read, FCB at DS:DX",0
  2418.     db    22h,"Random Write, FCB at DS:DX",0
  2419.     db    23h,"Set file size per FCB pattern at DS:DX",0
  2420.     db    24h,"Set random rec field in FCB at DS:DX",0
  2421.     db    25h,"Set Interrupt <AL> vector to DS:DX",0
  2422.     db    26h,"Create new segment at <DX>:0000",0
  2423.     db    27h,"Random Read of <CX> records, FCB at DS:DX",0
  2424.     db    28h,"Random Write of <CX> records, FCB at DS:DX",0
  2425.     db    29h,"Parse filename at DS:SI into FCB at ES:DI",0
  2426.     db    2ah,"Get year to CX, month to DH, day to DL",0
  2427.     db    2bh,"Set year to CX, month to DH, day to DL",0
  2428.     db    2ch,"Get CH=hours CL=mins DH=secs DL=tenths",0
  2429.     db    2dh,"Set hours=CH mins=CL secs=DH tenths=DL",0
  2430.     db    2eh,"IFF DL=0 then set VERIFY per AL",0
  2431.     db    2fh,"Get DTA to ES:BX",0
  2432.     db    30h,"Get DOS version to AL (major), AH (minor)",0
  2433.     db    31h,"Term/stay resident, DX=# para's AL=exit code",0
  2434.     db    33h,"Request (AL=0) or set (AL=1,DL=value) BREAK value",0
  2435.     db    34h,"Set ES:BX to DOS 'in-use' flag",0
  2436.     db    35h,"Set ES:BX to vector for INT # <AL>",0
  2437.     db    36h,"Get disk space for drive DL (0=default)",0
  2438.     db    38h,"Return country info to DS:DX",0
  2439.     db    39h,"Create directory per ASCIIZ at DS:DX",0
  2440.     db    3ah,"Remove directory per ASCIIZ at DS:DX",0
  2441.     db    3bh,"Change directory to ASCIIZ at DS:DX",0
  2442.     db    3ch,"Create file per ASCIIZ at DS:DX, attrib <CX>",0
  2443.     db    3dh,"Open file per ASCIIZ at DS:DX, access <AL>",0
  2444.     db    3eh,"Close file handle <BX>",0
  2445.     db    3fh,"Read <CX> bytes from file handle <BX> to DS:DX",0
  2446.     db    40h,"Write <CX> bytes from DS:DX to file handle <BX>",0
  2447.     db    41h,"Delete file per ASCIIZ at DS:DX",0
  2448.     db    42h,"LSEEK file handle <BX> <CX:DX> bytes, method <AL>",0
  2449.     db    43h,"Set (AL=1, CX=value) or get (AL=0) attrib for ASCIIZ at DS:DX",0
  2450.     db    44h,"IOCTL for file handle <BX>, func <AL>",0
  2451.     db    45h,"DUP file handle <BX> into <AX>",0
  2452.     db    46h,"Force DUP of handle <BX> into handle <CX>",0
  2453.     db    47h,"Get cur dir for drive <DL> (0=default) to DS:SI",0
  2454.     db    48h,"Allocate <BX> paragraphs, address to AX",0
  2455.     db    49h,"Free block starting at <ES>",0
  2456.     db    4ah,"Modify segment <ES> to be <BX> para's in size",0
  2457.     db    4bh,"EXEC file at ASCIIZ DS:DX, func <AL>",0
  2458.     db    4ch,"Terminate with exit code <AL>",0
  2459.     db    4dh,"Get EXIT return code to AX",0
  2460.     db    4eh,"Find first per ASCIIZ at DS:DX and attrib <CX>",0
  2461.     db    4fh,"Find next per current DTA",0
  2462.     db    54h,"Get VERIFY state to AL",0
  2463.     db    56h,"Rename filename at ASCIIZ DS:DX to ASCIIZ at ES:DI",0
  2464.     db    57h,"Get (AL=0) or set (AL=1) date/time for file handle <BX>",0
  2465.     db    59h,"Get extended error code",0
  2466.     db    5ah,"Create temp file per ASCIIZ DS:DX and attrib <CX>",0
  2467.     db    5bh,"Create new file per ASCIIZ DS:DX and attrib <CX>",0
  2468.     db    5ch,"Lock (AL=0) or unlock (AL=1) file handle <BX>",0
  2469.     db    62h,"Get PSP segment address to BX",080h
  2470.  
  2471. int21_line label byte
  2472.         db    0dh,0ah,"      DOS: "
  2473.         db    Edit_Call
  2474. int21_func    db    0
  2475.         dw    offset int21_functab
  2476.         dw    offset table_print
  2477.         db    Edit_End
  2478.  
  2479. ;**************************************************
  2480. ;
  2481. ; Interpret INT 21h BEFORE trace record at [SI]
  2482. ;
  2483. ;**************************************************
  2484.  
  2485. interp_21 proc    near
  2486.     push    dx
  2487.     push    ax
  2488.     mov    ax,[SI].B_ax        ;get AX at time of int
  2489.     mov    byte ptr int21_func,ah    ;use it to select function
  2490.     mov    dx,offset int21_line
  2491.     call    print_edit
  2492.     pop    ax
  2493.     pop    dx
  2494.     ret
  2495. interp_21 endp
  2496.  
  2497.     subttl    Interpretation - INT 25h and 26h (Absolute disk I/O)
  2498.     page
  2499. ;
  2500. ; Tables used to interpret INT's 25h and 26h
  2501. ;
  2502.  
  2503. int25_functab    label    byte
  2504.         db    025h,"Read",0
  2505.         db    026h,"Write",080h
  2506.  
  2507. int25_line    label    byte
  2508.         db    0dh,0ah,"      DOS Absolute "
  2509.         db    Edit_Call
  2510. int25_func    db    0
  2511.         dw    offset int25_functab
  2512.         dw    offset table_print
  2513.         db    " Drive:"
  2514.         db    Edit_Dec8
  2515. int25_drv    db    0
  2516.         db    " Sector:"
  2517.         db    Edit_Dec16
  2518. int25_sect    dw    0
  2519.         db    " #Sectors:"
  2520.         db    Edit_Dec16
  2521. int25_numsects    dw    0
  2522.         db    " Buf "
  2523.         db    Edit_Word
  2524. int25_seg    dw    0
  2525.         db    ":"
  2526.         db    Edit_Word
  2527. int25_off    dw    0
  2528.         db    Edit_End
  2529.  
  2530. ;**************************************************
  2531. ;
  2532. ; Interpret INT 25h or INT 26h BEFORE trace record at [SI]
  2533. ;
  2534. ;**************************************************
  2535.  
  2536. interp_25 proc    near
  2537.     push    dx
  2538.     push    ax
  2539.     mov    al,[SI].B_int        ;get INT that was done (25h or 26h)
  2540.     mov    int25_func,al        ;move to printline
  2541.     mov    ax,[SI].B_ax        ;get drive # from AL
  2542.     mov    int25_drv,al        ;move to printline
  2543.     mov    ax,[SI].B_dx        ;get starting sector # from DX
  2544.     mov    int25_sect,ax        ;move to printline
  2545.     mov    ax,[SI].B_cx        ;get # sectors from CX
  2546.     mov    int25_numsects,ax    ;move to printline
  2547.     mov    ax,[SI].B_ds        ;get buffer segment from DS
  2548.     mov    int25_seg,ax        ;move to printline
  2549.     mov    ax,[SI].B_bx        ;get buffer offset from BX
  2550.     mov    int25_off,ax        ;move to printline
  2551.     mov    dx,offset int25_line    ;now print edited line
  2552.     call    print_edit
  2553.     pop    ax
  2554.     pop    dx
  2555.     ret
  2556. interp_25 endp
  2557.  
  2558.     subttl    Periscope Interrupt Interface
  2559.     page
  2560.  
  2561. ;*****************************************
  2562. ;
  2563. ; This is the interrupt handler use by Periscope to access this code.
  2564. ; It may also be called by SHIFT-PrtSc.
  2565. ;
  2566. ; On entry, AH contains function:
  2567. ;
  2568. ;    1 - 8:   User Breakpoint checks (BU 1 thru BU 8, then GT)
  2569. ;    9 - FFh: User exits (/U 9 thru /U FFh)
  2570. ;    0FFh:    Called by PrtSc
  2571. ;
  2572. ;*****************************************
  2573.  
  2574.     db    "PS"            ;sentinel that Periscope checks for
  2575. periscope proc    far
  2576.  
  2577. ;
  2578. ; First, make very sure that we aren't being re-entered!!! This would
  2579. ; wipe out our stack which is already in use.
  2580. ;
  2581.  
  2582.     cli
  2583.     test    cs:stack_inuse,0ffh
  2584.     jz    periscope2        ;it's ok
  2585.  
  2586. periscope1:
  2587.  
  2588.     mov    al,0ffh            ;tell Periscope "No Break, No Command to be executed"
  2589.     iret                ;busy, call back later
  2590.  
  2591. periscope2:
  2592.  
  2593. ;
  2594. ; If we've been entered via Periscope User Break function (during single-stepping,
  2595. ; with BU 1 thru BU 8 in effect), then exit immediately. Things are slow
  2596. ; enough without us being executed when we have no Breakpoint checking to do.
  2597. ;
  2598.  
  2599.     cmp    ah,9            ;BU 1 thru BU 8?
  2600.     jb    periscope1        ;yes, exit
  2601.  
  2602.  
  2603. ;
  2604. ; On entry to this periscope int, we ought to save everything but AX,
  2605. ; and switch to our own stack. Periscope itself doesn't require this,
  2606. ; but the PrtSc routine assumes it.
  2607. ;
  2608.  
  2609.     mov    cs:stack_inuse,0ffh    ;mark our stack busy
  2610.     mov    cs:save_ss,ss
  2611.     mov    cs:save_sp,sp
  2612.     mov    ss,cs:our_cs
  2613.     mov    sp,offset our_tos
  2614.     push    cs:save_ss        ;save old stack stuff for later
  2615.     push    cs:save_sp
  2616.     push    bx
  2617.     push    cx
  2618.     push    dx
  2619.     push    si
  2620.     push    di
  2621.     push    es
  2622.     push    ds
  2623.     push    bp
  2624.     mov    ds,cs:our_cs        ;set DS to us for assume ds:code
  2625.     sti
  2626.  
  2627. ;
  2628. ; Give user stats about trace buffer size
  2629. ;
  2630.  
  2631.     mov    ax,offset last_byte    ;get # free bytes
  2632.     sub    ax,next_byte
  2633.     mov    word ptr size_freeb,ax
  2634.     mov    dx,offset size_msg
  2635.     call    print_edit
  2636.  
  2637. periscope_menu:
  2638.  
  2639. ;
  2640. ; Now display menu and get his selection, until we are to exit
  2641. ;
  2642.  
  2643.     mov    dx,offset mainmenu
  2644.     call    print_line        ;put up main menu
  2645.     call    feed            ;extra CRLF's for printer
  2646.     call    key            ;get keypress
  2647.     call    do_main            ;process it
  2648.     jc    periscope_menu        ;we are to loop back
  2649.     mov    dx,offset shadows    ;give him exit message
  2650.     call    print_line
  2651.  
  2652.  
  2653. periscope_exit:
  2654.  
  2655. ;
  2656. ; Restore regs and original stack. AX is already set to return result.
  2657. ;
  2658.  
  2659.     cli
  2660.     pop    bp
  2661.     pop    ds
  2662.     pop    es
  2663.     pop    di
  2664.     pop    si
  2665.     pop    dx
  2666.     pop    cx
  2667.     pop    bx
  2668.     pop    cs:save_sp    ;restore original stack
  2669.     pop    cs:save_ss
  2670.     mov    ss,cs:save_ss
  2671.     mov    sp,cs:save_sp
  2672.     mov    cs:stack_inuse,0    ;mark our stack not busy
  2673.     iret
  2674. periscope endp
  2675.  
  2676. mainmenu    db    0dh,0ah
  2677.         db    "(P)rinter (S)creen (E)nable (D)isable (F)CB (T)races (L)ist (C)lear (Q)uit$"
  2678.  
  2679. shadows        db    0dh,0ah
  2680.         db    "Back... to the shadows... AGAIN!"
  2681.         db    0dh,0ah,"$"
  2682.  
  2683. size_msg    label    byte
  2684.         db    0dh,0ah
  2685.         db    "TraceBuf Bytes:"
  2686.         db    Edit_Dec16
  2687.         dw    trace_size
  2688.         db    " Free Bytes:"
  2689.         db    Edit_Dec16
  2690. size_freeb    dw    0
  2691.         db    Edit_End
  2692.  
  2693.     subttl    INT 05 (SHIFT-PrtSc) Handler
  2694.     page
  2695. ;**************************************************
  2696. ;
  2697. ; This is another way (besides Periscope) to talk to the tracer, and
  2698. ; get it to report what it's found. This is not as clean a way as
  2699. ; via Periscope, but it beats nothing if the Periscope board isn't in
  2700. ; the system.
  2701. ;
  2702. ; This routine just calls the Periscope interrupt handler.
  2703. ;
  2704. ;**************************************************
  2705.  
  2706.     if    prt_scr
  2707.  
  2708. PrtSc    proc    far
  2709.     cli
  2710.     push    es
  2711.     push    ax
  2712.     mov    ax,050h            ;set ES to 0050:0000
  2713.     mov    es,ax            ;(the print-screen control byte)
  2714.     cmp    byte ptr es:[0],1    ;are we busy with previous request?
  2715.     jz    PrtSc_exit        ;yes, don't do anything
  2716.     mov    byte ptr es:[0],1    ;no, mark us busy now
  2717.     mov    ah,0ffh            ;call Periscope INT with special arg
  2718.     int    peri_int
  2719.     mov    byte ptr es:[0],0    ;mark us not busy now
  2720.  
  2721. PrtSc_exit:
  2722.     pop    ax
  2723.     pop    es
  2724.     iret
  2725. Prtsc    endp
  2726.  
  2727.     endif
  2728.  
  2729.     subttl  Startup (init) code
  2730.         page
  2731.  
  2732. ;********************************************************
  2733. ;
  2734. ; Startup code, which installs us in memory and sets up interrupts
  2735. ; to be handled.
  2736. ;
  2737. ;********************************************************
  2738.  
  2739. init:
  2740.     mov     our_cs,cs           ;save for handlers' use
  2741.     mov    test_cs,cs        ;start normalized CS for testing
  2742.     mov    ax,offset init        ;include all of resident part in it
  2743.     mov    cl,4
  2744.     shr    ax,cl
  2745.     add    test_cs,ax        ;done normalizing it
  2746.     mov    dx,offset copyright
  2747.     mov    ah,9
  2748.     int    021h
  2749.  
  2750. ;
  2751. ; Get printer base I/O address for use later
  2752. ;
  2753.  
  2754.     mov    ax,040h            ;point to parallel table at 0040:0008
  2755.     mov    es,ax
  2756.     mov    dx,es:[8]        ;get LPT1's base address
  2757.     mov    prt_base,dx        ;save it
  2758.     or    dx,dx            ;is there an LPT1?
  2759.     jnz    init2            ;yes, move on
  2760.     mov    dx,offset no_printer    ;no, give warning message...
  2761.     call    selvideo        ;...after switching to video
  2762.     call    print_line
  2763.  
  2764. init2:
  2765.  
  2766. ;
  2767. ; Init proper I/O mode
  2768. ;
  2769.  
  2770.     if    use_prt
  2771.     call    selprint
  2772.     else
  2773.     call    selvideo
  2774.     endif
  2775.  
  2776. ;
  2777. ; Install Periscope access interrupt # 'peri_int'
  2778. ;
  2779.  
  2780.     mov    al,peri_int        ;INT # being installed
  2781.     mov    ah,025h            ;DOS "Install Int Vector" func
  2782.     mov    dx,offset periscope    ;DS:DX = handler for this INT
  2783.     int    021h
  2784.  
  2785. ;
  2786. ; Install SHIFT-PrtSc interrupt
  2787. ;
  2788.  
  2789.     if    prt_scr
  2790.     mov    al,5            ;INT # being installed
  2791.     mov    ah,025h            ;DOS "Install Int Vector" func
  2792.     mov    dx,offset PrtSc        ;DS:DX = handler for this INT
  2793.     int    021h
  2794.     endif
  2795.     
  2796. ;
  2797. ; Install interrupt vectors for any active ICT's
  2798. ;
  2799.  
  2800.     mov    cx,8            ;number of ICT's
  2801.     xor    si,si            ;Start with ICT # 0
  2802.  
  2803. init5:
  2804.     mov    bx,ict_index[si]    ;get pointer to an ICT
  2805.     mov    al,[bx].ICT_flags    ;get flags to AL
  2806.     test    al,F_ACTIVE        ;is this ICT active?
  2807.     jz    init10            ;no, move on to next one
  2808.  
  2809. ; ------- Validate type of interrupt exit
  2810.  
  2811.     and    al,F_RET+F_RET2+F_IRET
  2812.     cmp    al,F_RET
  2813.     jz    init6            ;this one's legal
  2814.     cmp    al,F_RET2
  2815.     jz    init6            ;this one's legal
  2816.     cmp    al,F_IRET
  2817.     jz    init6            ;this one's legal
  2818.     mov    dx,offset bad_exit    ;bad field, give error message
  2819.  
  2820. init5b:
  2821.  
  2822. ;
  2823. ; Print error message at DS:DX and mark ICT de-activated
  2824. ;
  2825.  
  2826.     push    dx            ;save error message text
  2827.     mov    ax,si            ;get ICT # for error message
  2828.     shr    ax,1
  2829.     and    al,7            ;(just in case)
  2830.     or    al,'0'            ;make into ASCII digit
  2831.     mov    err_ict,al        ;move into error header
  2832.     mov    dx,offset err_msg    ;print error header first
  2833.     call    print_line
  2834.     pop    dx            ;recover error message itself
  2835.     call    print_line        ;display it
  2836.     xor    [bx].ICT_flags,F_ACTIVE    ;de-activate this ICT
  2837.     jmp    short init10        ;goto next ICT
  2838.  
  2839. init6:
  2840.     mov    al,[bx].ICT_intnum    ;get int number to AL
  2841.  
  2842.     if    prt_scr
  2843.     cmp    al,5            ;trying to trace INT 5?
  2844.     jnz    init6b            ;no, it's all right
  2845.     mov    dx,offset two_prtscrs    ;yes, give error message
  2846.     jmp    init5b
  2847.  
  2848. init6b:
  2849.     endif
  2850.  
  2851.     mov    ah,035h            ;get current vector for this INT
  2852.     push    bx            ;(save ICT pointer!!!)
  2853.     int    021h
  2854.     mov    dx,bx            ;put vector's offset somewhere safe
  2855.     pop    bx            ;(restore ICT pointer!!!)
  2856.  
  2857.     mov    word ptr [bx].ICT_orig_hndlr,dx
  2858.     mov    word ptr [bx].ICT_orig_hndlr+2,es
  2859.  
  2860.     mov    dx,hndlr_index[si]    ;DS:DX = new vector for this INT
  2861.     mov    ah,025h            ;tell DOS to install it
  2862.     int    021h            ;(intnum still in AL)
  2863.  
  2864. init10:
  2865.     add    si,2            ;up to next ICT
  2866.     loop    init5            ;till done all ICT's
  2867.  
  2868. ;
  2869. ; List final ICT's
  2870. ;
  2871.  
  2872.     mov    dx,offset final_msg
  2873.     call    print_line
  2874.     call    disp_active        ;display all active ICT's
  2875.     call    crlf
  2876.  
  2877. ;
  2878. ; Terminate and stay resident
  2879. ;
  2880.  
  2881.     mov    dx,offset intro_msg    ;give him intro message
  2882.     call    print_line
  2883.     mov    al,peri_int
  2884.     call    print_hex
  2885.     call    crlf
  2886.     call    feed            ;extra CRLF's for printer
  2887.     mov     dx,offset init
  2888.     int     027h
  2889.  
  2890. ;********************************************************
  2891. ;
  2892. ; Startup messages (lost once we're resident)
  2893. ;
  2894. ;********************************************************
  2895.  
  2896. copyright    db    0dh,0ah
  2897.         db    "TRACE - Interrupt Tracer version 1.2 2/26/86"
  2898.         db    0dh,0ah
  2899.         db    0dh,0ah
  2900.         db    "Written by Joan Riff for:"
  2901.         db    0dh,0ah
  2902.         db    "Computerwise Consulting Services P.O. Box 813, McLean VA 22101  (703) 280-2809"
  2903.         db    0dh,0ah
  2904.         db    0dh,0ah
  2905.         db    "Placed in the public domain. There ain't one person in a thousand qualified to"
  2906.         db    0dh,0ah
  2907.         db    "understand or use this thing, so why charge for it?"
  2908.         db    0dh,0ah,"$"
  2909.  
  2910.  
  2911. intro_msg    db    0dh,0ah
  2912.         db    0dh,0ah
  2913.         db    "Trace is now resident."
  2914.         db    0dh,0ah
  2915.         db    "Use '/U 9' Periscope command"
  2916.         if    prt_scr
  2917.         db    " (or SHIFT-PrtSc)"
  2918.         endif
  2919.         db    " for access."
  2920.         db    0dh,0ah
  2921.         db    "When you run Periscope, include command-line arg /I:$"
  2922. bad_exit    db    "has a bad Exit field. ICT deactivated.$"
  2923. two_prtscrs    db    "overlays SHIFT-PrtSc. ICT deactivated.$"
  2924. no_printer    db    0dh,0ah,"*** Warning: LPT1 not available$"
  2925. err_msg        db    0dh,0ah,"*** ICT #"
  2926. err_ict        db    "0 $"
  2927. final_msg    db    0dh,0ah
  2928.         db    0dh,0ah,"Final ICT's:",0dh,0ah,"$"
  2929.  
  2930. code    ends
  2931.     end     start
  2932.